Category

Development Platform
Home > SourceCode/Document > Linux-Unix program > View Code
memset.S
Package: linux-2.4.20.tar.gz　[view]
Upload User: jlfgdled
Upload Date: 2013-04-10
Package Size: 33168k
Code Size: 1k
Category:

Linux-Unix program

Development Platform:

Unix_Linux

memset.S：Code Content
  1. /* Copyright 2002 Andi Kleen, SuSE Labs */
  3. /*
  4.  * ISO C memset - set a memory block to a byte value.
  5.  *
  6.  * rdi   destination
  7.  * rsi   value (char) 
  8.  * rdx   count (bytes) 
  9.  * 
  10.  * rax   original destination
  11.  */
  12.   .globl __memset
  13. .globl memset
  14. .p2align
  15. memset:
  16. __memset:
  17. movq %rdi,%r10
  18. movq %rdx,%r11
  20. /* expand byte value  */
  21. movzbl %sil,%ecx
  22. movabs $0x0101010101010101,%rax
  23. mul    %rcx /* with rax, clobbers rdx */
  25. /* align dst */
  26. movl  %edi,%r9d
  27. andl  $7,%r9d
  28. jnz  bad_alignment
  29. after_bad_alignment:
  31. movq %r11,%rcx
  32. movl $64,%r8d
  33. shrq $6,%rcx
  34. jz  handle_tail
  36. loop_64:
  37. movq  %rax,(%rdi) 
  38. movq  %rax,8(%rdi) 
  39. movq  %rax,16(%rdi) 
  40. movq  %rax,24(%rdi) 
  41. movq  %rax,32(%rdi) 
  42. movq  %rax,40(%rdi) 
  43. movq  %rax,48(%rdi) 
  44. movq  %rax,56(%rdi) 
  45. addq    %r8,%rdi
  46. decl   %ecx
  47. jnz    loop_64
  49. /* Handle tail in loops. The loops should be faster than hard
  50.    to predict jump tables. */ 
  51. handle_tail:
  52. movl %r11d,%ecx
  53. andl    $63&(~7),%ecx
  54. jz  handle_7
  55. shrl $3,%ecx
  56. loop_8:
  57. movq  %rax,(%rdi) 
  58. addq    $8,%rdi
  59. decl   %ecx
  60. jnz    loop_8
  62. handle_7:
  63. movl %r11d,%ecx
  64. andl $7,%ecx
  65. jz      ende
  66. loop_1:
  67. movb  %al,(%rdi)
  68. addq $1,%rdi
  69. decl    %ecx
  70. jnz     loop_1
  72. ende:
  73. movq %r10,%rax
  74. ret
  76. bad_alignment:
  77. cmpq $7,%r11
  78. jbe handle_7
  79. movq %rax,(%rdi) /* unaligned store */
  80. movq $8,%r8
  81. subq %r9,%r8 
  82. addq %r8,%rdi
  83. subq %r8,%r11
  84. jmp after_bad_alignment