ARM-PowerPC-ColdFire-MIPS

Development Platform:
C/C++

2410init.s：Code Content
							;=========================================
; NAME: 2410INIT.S
; DESC: C start up codes
;=========================================
;Pre-defined constants
USERMODE    		EQU 	0x10
FIQMODE     		EQU 	0x11
IRQMODE     		EQU 	0x12
SVCMODE     		EQU 	0x13
ABORTMODE   		EQU 	0x17
UNDEFMODE   		EQU 	0x1b
MODEMASK    		EQU 	0x1f
NOINT       		EQU 	0xc0
;Start address of each stacks,
_STACK_BASEADDRESS	EQU 	0x33ff8000  
_MMUTT_STARTADDRESS	EQU 	0x33ff8000  
_ISR_STARTADDRESS	EQU 	0x33ffff00
;The location of stacks
UserStack			EQU		(_STACK_BASEADDRESS-0x3800)	;0x33ff4800 ~ 
SVCStack        	EQU		(_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack			EQU		(_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack			EQU		(_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack        	EQU		(_STACK_BASEADDRESS-0x1000)	;0x33ff7000 ~
FIQStack			EQU		(_STACK_BASEADDRESS-0x0)	;0x33ff8000 ~ 
    	MACRO
$HandlerLabel 		HANDLER $HandleLabel
$HandlerLabel
	sub		sp,sp,#4        	;decrement sp(to store jump address)
	stmfd	sp!,{r0}        	;PUSH the work register to stack(lr does't push because it return to original address)
	ldr     r0,=$HandleLabel	;load the address of HandleXXX to r0
	ldr     r0,[r0]         	;load the contents(service routine start address) of HandleXXX
	str     r0,[sp,#4]      	;store the contents(ISR) of HandleXXX to stack
	ldmfd   sp!,{r0,pc}     	;POP the work register and pc(jump to ISR)
	MEND
	
	IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
	IMPORT  |Image$$RW$$Base|   ; Base of RAM to initialise
	IMPORT  |Image$$ZI$$Base|   ; Base and limit of area
	IMPORT  |Image$$ZI$$Limit|  ; to zero initialise
	
	IMPORT  Main    			; The main entry of mon program 
	
	AREA    Init,CODE,READONLY
	ENTRY 
	
	b		ResetHandler  
	b		HandlerUndef		;handler for Undefined mode
	b		HandlerSWI			;handler for SWI interrupt
	b		HandlerPabort		;handler for PAbort
	b		HandlerDabort		;handler for DAbort
	b		.					;reserved
	b		HandlerIRQ			;handler for IRQ interrupt 
	b		HandlerFIQ			;handler for FIQ interrupt
	LTORG   
HandlerFIQ      HANDLER 	HandleFIQ
HandlerIRQ      HANDLER 	HandleIRQ
HandlerUndef    HANDLER 	HandleUndef
HandlerSWI      HANDLER 	HandleSWI
HandlerDabort   HANDLER 	HandleDabort
HandlerPabort   HANDLER 	HandlePabort
IsrIRQ  
	sub		sp,sp,#4       		;reserved for PC
	stmfd	sp!,{r8-r9}   
	
	ldr		r9,=0x4a000014		;INTOFFSET
	ldr		r9,[r9]
	ldr		r8,=HandleEINT0
	add		r8,r8,r9,lsl #2
	ldr		r8,[r8]
	str		r8,[sp,#8]
	ldmfd	sp!,{r8-r9,pc}
;=======
; ENTRY  
;=======
ResetHandler
	ldr		r0,=0x53000000		;WTCON,watch dog disable 
	ldr		r1,=0x0         
	str		r1,[r0]
	ldr		r0,=0x4a000008		;INTMSK
	ldr		r1,=0xffffffff  	;all interrupt disable
	str		r1,[r0]
	ldr		r0,=0x4a00001c		;INTSUBMSK
	ldr		r1,=0x7ff			;all sub interrupt disable
	str		r1,[r0]
	;To reduce PLL lock time   
	ldr		r0,=0x4c000000		;LOCKTIME
	ldr		r1,=0xffffff
	str		r1,[r0]
        
	;Configure MPLL,Fin=12MHz,Fout=50MHz,M_MDIV=0x5c,M_PDIV=0x4,M_SDIV=0x2
	ldr		r0,=0x4c000004;MPLLCON          
	ldr		r1,=((0x5c<<12)+(0x4<<4)+0x2)
	str		r1,[r0]
	;Set memory control registers
   	ldr		r0,=SMRDATA
	ldr		r1,=0x48000000 		;BWSCON
	add		r2, r0, #52			;End address of SMRDATA
0       
	ldr		r3, [r0], #4    
	str		r3, [r1], #4    
	cmp		r2, r0		
	bne		%B0
	
    	;Initialize stacks
	bl		InitStacks
	
  	; Setup IRQ handler
	ldr		r0,=HandleIRQ       ;This routine is needed
	ldr		r1,=IsrIRQ          ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
	str		r1,[r0]
	;Copy and paste RW data/zero initialized data
	ldr		r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
	ldr		r1, =|Image$$RW$$Base|  ; and RAM copy
	ldr		r3, =|Image$$ZI$$Base|  
	
	;Zero init base => top of initialised data
	cmp		r0, r1      			;Check that they are different
	beq		%F2
1       
	cmp	r1, r3      				;Copy init data
	ldrcc	r2, [r0], #4   			;--> LDRCC r2, [r0] + ADD r0, r0, #4         
	strcc	r2, [r1], #4   			;--> STRCC r2, [r1] + ADD r1, r1, #4
	bcc		%B1
2       
	ldr		r1, =|Image$$ZI$$Limit| ;Top of zero init segment
	mov		r2, #0
3       
	cmp		r3, r1      			;Zero init
	strcc	r2, [r3], #4
	bcc		%B3
	bl		Main        			;Don't use main() because ......
   	b	.                       
;function initializing stacks
InitStacks
	mrs		r0,cpsr
	bic		r0,r0,#MODEMASK
	orr		r1,r0,#UNDEFMODE|NOINT
	msr		cpsr_cxsf,r1			;UndefMode
	ldr		sp,=UndefStack
	
	orr		r1,r0,#ABORTMODE|NOINT
	msr		cpsr_cxsf,r1			;AbortMode
	ldr		sp,=AbortStack
	orr		r1,r0,#IRQMODE|NOINT
	msr		cpsr_cxsf,r1			;IRQMode
	ldr		sp,=IRQStack
    
	orr		r1,r0,#FIQMODE|NOINT
	msr		cpsr_cxsf,r1			;FIQMode
	ldr		sp,=FIQStack
	bic		r0,r0,#MODEMASK|NOINT
	orr		r1,r0,#SVCMODE
	msr		cpsr_cxsf,r1			;SVCMode
	ldr		sp,=SVCStack
	
	;USER mode has not be initialized.	
	mov	pc,lr 
	;The LR register won't be valid if the current mode is not SVC mode.
	
	LTORG
SMRDATA DATA
	DCD 	0x22111120	;GCS0=GCS6=GCS7=32bit,other=16bit
	DCD 	0x0700		;GCS0 Tacs=Tcos=Tcoh=Tcah=Tacp=1clk,Tacc=14clk,PMC=0
	DCD 	0x0700		;GCS1 Tacs=Tcos=Tcoh=Tcah=Tacp=1clk,Tacc=14clk,PMC=0
	DCD 	0x0700		;GCS2 Tacs=Tcos=Tcoh=Tcah=Tacp=1clk,Tacc=14clk,PMC=0
	DCD 	0x0700		;GCS3 Tacs=Tcos=Tcoh=Tcah=Tacp=1clk,Tacc=14clk,PMC=0
	DCD 	0x0700		;GCS4 Tacs=Tcos=Tcoh=Tcah=Tacp=1clk,Tacc=14clk,PMC=0
	DCD 	0x0700		;GCS5 Tacs=Tcos=Tcoh=Tcah=Tacp=1clk,Tacc=14clk,PMC=0
	DCD 	0x18005    	;GCS6 SDRAM,Trcd=3clk,SCAN=9bit
	DCD 	0x18005    	;GCS7 SDRAM,Trcd=3clk,SCAN=9bit
	DCD 	0x8c0459	;REFEN=1,TREFMD=0,Trp=0,Tsrc=3,REFCNT=1113
	DCD 	0x32       	;SCKE_EN=SCLK_EN=1 SCLK power saving mode, BANKSIZE 128M/128M
	DCD 	0x30        ;MRSR6 CL=3clk
	DCD 	0x30        ;MRSR7
    	ALIGN
    	AREA RamData, DATA, READWRITE
        ^   _ISR_STARTADDRESS
HandleReset 	#   4
HandleUndef 	#   4
HandleSWI   	#   4
HandlePabort    #   4
HandleDabort    #   4
HandleReserved  #   4
HandleIRQ   	#   4
HandleFIQ   	#   4
HandleEINT0   	#   4
HandleEINT1   	#   4
HandleEINT2   	#   4
HandleEINT3   	#   4
HandleEINT4_7	#   4
HandleEINT8_23	#   4
HandleRSV6		#   4
HandleBATFLT   	#   4
HandleTICK   	#   4
HandleWDT		#   4
HandleTIMER0 	#   4
HandleTIMER1 	#   4
HandleTIMER2 	#   4
HandleTIMER3 	#   4
HandleTIMER4 	#   4
HandleUART2  	#   4
HandleLCD 		#   4
HandleDMA0		#   4
HandleDMA1		#   4
HandleDMA2		#   4
HandleDMA3		#   4
HandleMMC		#   4
HandleSPI0		#   4
HandleUART1		#   4
HandleRSV24		#   4
HandleUSBD		#   4
HandleUSBH		#   4
HandleIIC   	#   4
HandleUART0 	#   4
HandleSPI1 		#   4
HandleRTC 		#   4
HandleADC 		#   4
        END

						