Category

Development Platform
Home > SourceCode/Document > Embeded-SCM Develop > SCM > View Code
USB18.asm
Package: USBFM.zip　[view]
Upload User: wang202020
Upload Date: 2021-02-07
Package Size: 182k
Code Size: 62k
Category:

SCM

Development Platform:

HTML/CSS

USB18.asm：Code Content
  1. ; USB18.ASM
  3. ; Put Address into source pointer
  4. mSetSourcePointer macro Address
  5. movlw low (Address)
  6. movwf pSrc
  7. movlw high (Address)
  8. movwf pSrc + 1
  9. endm
  11. ; Put Address into destination pointer
  12. mSetDestinationPointer macro Address
  13. movlw low (Address)
  14. movwf pDst
  15. movlw high (Address)
  16. movwf pDst + 1
  17. endm
  19. ; Get count from first location of ROM table pointed to by pSrc
  20. mGetRomTableCount macro
  21. movff pSrc, TBLPTRL ; Set source address
  22. movff pSrc + 1, TBLPTRH
  23. clrf TBLPTRU
  24.         tblrd   * ; Read count
  25. movff TABLAT, wCount
  26. clrf wCount + 1
  27. endm
  30. ; From usb9.c  line 70
  31. ;/******************************************************************************
  32. ; * Function:        void USBCheckStdRequest(void)
  33. ; *
  34. ; * PreCondition:    None
  35. ; *
  36. ; * Input:           None
  37. ; *
  38. ; * Output:          None
  39. ; *
  40. ; * Side Effects:    None
  41. ; *
  42. ; * Overview:        This routine checks the setup data packet to see if it
  43. ; *                  knows how to handle it
  44. ; *
  45. ; * Note:            None
  46. ; *****************************************************************************/
  47. USBCheckStdRequest
  48. movlb high 0x400 ; Point to proper bank
  49. movf SetupPkt, W ; RequestType = STANDARD?
  50. andlw 0x60 ; Mask to proper bits
  51. sublw (STANDARD) << 5
  52. bnz USBCheckStdRequestExit ; No
  53. movlw SET_ADR ; Handle request
  54. cpfseq SetupPkt + bRequest
  55. bra USBCheckStdRequest1
  56. movlw ADR_PENDING_STATE
  57. movwf usb_device_state
  58. bra USBStdSetSessionOwnerUSB9
  60. ; GET_DESCRIPTOR request?
  61. USBCheckStdRequest1
  62. movlw GET_DSC
  63. cpfseq SetupPkt + bRequest
  64. bra USBCheckStdRequest2
  65. bra USBStdGetDscHandler
  67. ; GET_CONFIGURATION request?
  68. USBCheckStdRequest2
  69. movlw GET_CFG
  70. cpfseq SetupPkt + bRequest
  71. bra USBCheckStdRequest3
  72. mSetSourcePointer usb_active_cfg
  73. movlw 1
  74. movwf wCount
  75. clrf wCount + 1
  76. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  77. bra USBStdSetSessionOwnerUSB9
  79. ; SET_CONFIGURATION request?
  80. USBCheckStdRequest3
  81. movlw SET_CFG
  82. cpfseq SetupPkt + bRequest
  83. bra USBCheckStdRequest4
  84. bra USBStdSetCfgHandler
  86. ; GET_STATUS request?
  87. USBCheckStdRequest4
  88. movlw GET_STATUS
  89. cpfseq SetupPkt + bRequest
  90. bra USBCheckStdRequest5
  91. bra USBStdGetStatusHandler
  93. ; CLEAR_FEATURE request?
  94. USBCheckStdRequest5
  95. movlw CLR_FEATURE
  96. cpfseq SetupPkt + bRequest
  97. bra USBCheckStdRequest6
  98. bra USBStdFeatureReqHandler
  100. ; SET_FEATURE request?
  101. USBCheckStdRequest6
  102. movlw SET_FEATURE
  103. cpfseq SetupPkt + bRequest
  104. bra USBCheckStdRequest7
  105. bra USBStdFeatureReqHandler
  107. ; GET_INTERFACE request?
  108. USBCheckStdRequest7
  109. movlw GET_INTF
  110. cpfseq SetupPkt + bRequest
  111. bra USBCheckStdRequest8
  112. mSetSourcePointer usb_alt_intf
  113. movf SetupPkt + bIntfID, W
  114. addwf pSrc, F
  115. movlw 1
  116. movwf wCount
  117. clrf wCount + 1
  118. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  119. bra USBStdSetSessionOwnerUSB9
  121. ; SET_INTERFACE request?
  122. USBCheckStdRequest8
  123. movlw SET_INTF
  124. cpfseq SetupPkt + bRequest
  125. return
  126. lfsr 2, usb_alt_intf
  127. movf SetupPkt + bIntfID, W
  128. movff SetupPkt + bAltID, PLUSW2
  129. ; Branch here after decoding one of the above USB standard requests.
  130. ; Assign a value to ctrl_trf_session_owner, to prevent stalling
  131. USBStdSetSessionOwnerUSB9
  132. movlw MUID_USB9
  133. movwf ctrl_trf_session_owner
  134. USBCheckStdRequestExit
  135. return
  137. ; From usb9.c  line 136
  138. ;/******************************************************************************
  139. ; * Function:        void USBStdGetDscHandler(void)
  140. ; *
  141. ; * PreCondition:    None
  142. ; *
  143. ; * Input:           None
  144. ; *
  145. ; * Output:          None
  146. ; *
  147. ; * Side Effects:    None
  148. ; *
  149. ; * Overview:        This routine handles the standard GET_DESCRIPTOR request.
  150. ; *                  It utilizes tables dynamically looks up descriptor size.
  151. ; *                  This routine should never have to be modified if the tables
  152. ; *                  in usbdsc.c are declared correctly.
  153. ; *
  154. ; * Note:            None
  155. ; *****************************************************************************/
  156. USBStdGetDscHandler
  157. ; movlb high 0x400 ; Point to proper bank
  158. movlw 0x80
  159. cpfseq SetupPkt + bmRequestType
  160. return
  161. movlw DSC_DEV
  162. cpfseq SetupPkt + bDscType
  163. bra USBStdGetDscHandler1
  164. mSetSourcePointer DeviceDescriptor
  165. mGetRomTableCount ; Set wCount
  166. bsf usb_stat, ctrl_trf_mem ; Indicate ROM
  167. bra USBStdSetSessionOwnerUSB9
  168. USBStdGetDscHandler1
  169. movlw DSC_CFG
  170. cpfseq SetupPkt + bDscType
  171. bra USBStdGetDscHandler2
  172. mSetSourcePointer Config1
  173. movlw low Config1Len ; Set wCount to total length
  174. movwf TBLPTRL
  175. movlw high Config1Len
  176. movwf TBLPTRH
  177. clrf TBLPTRU
  178. tblrd *+ ; Read count low
  179. movff TABLAT, wCount
  180. tblrd *+ ; Ignore RETLW opcode
  181. tblrd *+ ; Read count high
  182. movff TABLAT, wCount + 1
  183. bsf usb_stat, ctrl_trf_mem ; Indicate ROM
  184. bra USBStdSetSessionOwnerUSB9
  185. USBStdGetDscHandler2
  186. movlw DSC_STR
  187. cpfseq SetupPkt + bDscType
  188. return
  189. clrf TBLPTRU
  190. clrf TBLPTRH
  191. rlncf SetupPkt + bDscIndex, W ; Index * 2
  192. addlw low (USB_SD_Ptr) ; Add element offset to low address
  193. movwf TBLPTRL
  194. movlw high (USB_SD_Ptr)
  195. addwfc TBLPTRH, F
  196.         tblrd   *+ ; Get the data to TABLAT and move pointer forward
  197. movff TABLAT, pSrc ; Get low source address
  198.         tblrd   *
  199. movff TABLAT, pSrc + 1 ; Get high source address
  200. mGetRomTableCount ; Set wCount
  201. bsf usb_stat, ctrl_trf_mem ; Indicate ROM
  202. bra USBStdSetSessionOwnerUSB9
  205. ; From usb9.c  line 180
  206. ;/******************************************************************************
  207. ; * Function:        void USBStdSetCfgHandler(void)
  208. ; *
  209. ; * PreCondition:    None
  210. ; *
  211. ; * Input:           None
  212. ; *
  213. ; * Output:          None
  214. ; *
  215. ; * Side Effects:    None
  216. ; *
  217. ; * Overview:        This routine first disables all endpoints by clearing
  218. ; *                  UEP registers. It then configures (initializes) endpoints
  219. ; *                  specified in the modifiable section.
  220. ; *
  221. ; * Note:            None
  222. ; *****************************************************************************/
  223. USBStdSetCfgHandler
  224. ; movlb high 0x400 ; Point to proper bank
  225. movlw MUID_USB9
  226. movwf ctrl_trf_session_owner
  227. lfsr 2, UEP1 ; Reset all non-EP0 UEPn registers
  228. movlw 15
  229. USBStdSetCfgHandlerClearEPLoop
  230. clrf POSTINC2
  231. decfsz WREG, F
  232. bra USBStdSetCfgHandlerClearEPLoop
  233. lfsr 2, usb_alt_intf ; Clear usb_alt_intf array
  234. movlw MAX_NUM_INT
  235. USBStdSetCfgHandlerClearAltLoop
  236. clrf POSTINC2
  237. decfsz WREG, F
  238. bra USBStdSetCfgHandlerClearAltLoop
  239. movf SetupPkt + bCfgValue, W
  240. movwf usb_active_cfg
  241. bnz USBStdSetCfgHandler1
  242. movlw ADDRESS_STATE ; SetupPkt + bCfgValue = 0
  243. movwf usb_device_state
  244. return
  245. USBStdSetCfgHandler1
  246. movlw CONFIGURED_STATE
  247. movwf usb_device_state
  248. #ifdef USB_USE_HID
  249. rcall HIDInitEP
  250. #endif
  251. #ifdef USB_USE_CDC
  252. rcall CDCInitEP
  253. #endif
  254. return
  257. ; From usb9.c  line 224
  258. ;/******************************************************************************
  259. ; * Function:        void USBStdGetStatusHandler(void)
  260. ; *
  261. ; * PreCondition:    None
  262. ; *
  263. ; * Input:           None
  264. ; *
  265. ; * Output:          None
  266. ; *
  267. ; * Side Effects:    None
  268. ; *
  269. ; * Overview:        This routine handles the standard GET_STATUS request
  270. ; *
  271. ; * Note:            None
  272. ; *****************************************************************************/
  273. USBStdGetStatusHandler
  274. ; movlb high 0x400 ; Point to proper bank
  275. clrf CtrlTrfData ; Initialize content
  276. clrf CtrlTrfData + 1
  277. movf SetupPkt, W ; Recipient = RCPT_DEV?
  278. andlw 0x1f ; Mask to lower 5 bits
  279. sublw RCPT_DEV
  280. bnz USBStdGetStatusHandler1 ; No
  281. ;
  282. ; Recipient of this Setup packet was "Device": set bits to indicate power & remote wakeup
  283. ; Decoding of "Self-powered" & "Remote Wakeup"
  284. ; _byte0: bit0: Self-Powered Status [0] Bus-Powered [1] Self-Powered
  285. ;         bit1: RemoteWakeup        [0] Disabled    [1] Enabled
  286. ;
  287. #ifdef USB_SELF_POWER
  288. bsf CtrlTrfData, 0
  289. #endif
  290. btfsc usb_stat, RemoteWakeup
  291. bsf CtrlTrfData, 1
  292. bra USBStdGetStatusSetSessionOwner
  293. ;
  294. USBStdGetStatusHandler1
  295. movf SetupPkt, W ; Recipient = RCPT_INTF?
  296. andlw 0x1f ; Mask to lower 5 bits
  297. sublw RCPT_INTF
  298. bnz USBStdGetStatusHandler2 ; No
  299. ;
  300. ; Recipient of this Setup packet was "Interface": No data to update
  301. bra USBStdGetStatusSetSessionOwner
  302. ;
  303. USBStdGetStatusHandler2
  304. movf SetupPkt, W ; Recipient = RCPT_EP?
  305. andlw 0x1f ; Mask to lower 5 bits
  306. sublw RCPT_EP
  307. bnz USBStdGetStatusHandler3 ; No
  308. ;
  309. ; Recipient of this Setup packet was "Endpoint"
  310. rcall USBCalcEPAddress ; Put endpoint buffer address in FSR2
  311. movf INDF2, W
  312. andlw _BSTALL
  313. bz USBStdGetStatusSetSessionOwner
  314. bsf CtrlTrfData, 0
  315. USBStdGetStatusSetSessionOwner
  316. movlw MUID_USB9
  317. movwf ctrl_trf_session_owner
  318. USBStdGetStatusHandler3
  319. movlw MUID_USB9
  320. cpfseq ctrl_trf_session_owner
  321. return
  322. mSetSourcePointer CtrlTrfData
  323. movlw 2 ; Set count
  324. movwf wCount
  325. clrf wCount + 1
  326. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  327. return
  329. ; From usb9.c  line 281
  330. ;/******************************************************************************
  331. ; * Function:        void USBStdFeatureReqHandler(void)
  332. ; *
  333. ; * PreCondition:    None
  334. ; *
  335. ; * Input:           None
  336. ; *
  337. ; * Output:          None
  338. ; *
  339. ; * Side Effects:    None
  340. ; *
  341. ; * Overview:        This routine handles the standard SET & CLEAR FEATURES
  342. ; *                  requests
  343. ; *
  344. ; * Note:            None
  345. ; *****************************************************************************/
  346. USBStdFeatureReqHandler
  347. ; movlb high 0x400 ; Point to proper bank
  348. movlw DEVICE_REMOTE_WAKEUP ; If Feature = DEVICE_REMOTE_WAKEUP &
  349. cpfseq SetupPkt + bFeature
  350. bra USBStdFeatureReqHandler1
  351. movf SetupPkt, W ; Recipient = RCPT_DEV?
  352. andlw 0x1f ; Mask to lower 5 bits
  353. sublw RCPT_DEV
  354. bnz USBStdFeatureReqHandler1 ; No
  355. bsf usb_stat, RemoteWakeup ; Preset RemoteWakeup to 1
  356. movlw SET_FEATURE ; Request = SET_FEATURE?
  357. cpfseq SetupPkt + bRequest
  358. bcf usb_stat, RemoteWakeup ; No, RemoteWakeup = 0
  359. bra USBStdSetSessionOwnerUSB9
  360. USBStdFeatureReqHandler1
  361. movlw ENDPOINT_HALT ; If Feature = ENDPOINT_HALT &
  362. cpfseq SetupPkt + bFeature
  363. USBStdFeatureReqHandlerExit
  364. return
  365. movf SetupPkt, W ; Recepient = RCPT_EP &
  366. andlw 0x1f ; Mask to lower 5 bits
  367. sublw RCPT_EP
  368. bnz USBStdFeatureReqHandlerExit
  369. movf SetupPkt + bEPID, W ; EPNum != 0
  370. andlw 0x0f ; Mask to EPNum
  371. bz USBStdFeatureReqHandlerExit
  372. rcall USBCalcEPAddress ; Put endpoint buffer address in FSR2
  373. movlw SET_FEATURE ; Request = SET_FEATURE?
  374. cpfseq SetupPkt + bRequest
  375. bra USBStdFeatureReqHandler2 ; No
  376. movlw _USIE|_BSTALL
  377. movwf INDF2 ; Put in endpoint buffer
  378. bra USBStdSetSessionOwnerUSB9
  379. USBStdFeatureReqHandler2
  380. movlw _UCPU ; IN
  381. btfss SetupPkt + bEPID, EPDir ; EPDir = 1 (IN)?
  382. movlw _USIE|_DAT0|_DTSEN ; No - OUT
  383. movwf INDF2 ; Put in endpoint buffer
  384. bra USBStdSetSessionOwnerUSB9
  387. ; Put endpoint buffer address in FSR2 (ep0Bo+(EPNum*8)+(EPDir*4))
  388. USBCalcEPAddress
  389. lfsr 2, ep0Bo ; Point FSR2 to beginning of buffer area
  390. rlncf SetupPkt + bEPID, W ; Move endpoint direction to C
  391. rlcf SetupPkt + bEPID, W ; Endpoint number * 8 (roll in ep direction)
  392. rlncf WREG, F
  393. rlncf WREG, F
  394. addwf FSR2L, F ; Add to FSR2 (can't overflow to FSR2H)
  395. return
  399. ; From usbctrltrf.c line 78
  400. ;/******************************************************************************
  401. ; * Function:        void USBCtrlEPService(void)
  402. ; *
  403. ; * PreCondition:    USTAT is loaded with a valid endpoint address.
  404. ; *
  405. ; * Input:           None
  406. ; *
  407. ; * Output:          None
  408. ; *
  409. ; * Side Effects:    None
  410. ; *
  411. ; * Overview:        USBCtrlEPService checks for three transaction types that
  412. ; *                  it knows how to service and services them:
  413. ; *                  1. EP0 SETUP
  414. ; *                  2. EP0 OUT
  415. ; *                  3. EP0 IN
  416. ; *                  It ignores all other types (i.e. EP1, EP2, etc.)
  417. ; *
  418. ; * Note:            None
  419. ; *****************************************************************************/
  420. USBCtrlEPService
  421. ; movlb high 0x400 ; Point to proper bank
  422. movlw EP00_OUT
  423. cpfseq USTAT
  424. bra USBCtrlEPService1
  425. movf ep0Bo + Stat, W
  426. andlw 0x3c ; Mask to PID
  427. sublw (SETUP_TOKEN) << 2
  428. bz USBCtrlTrfSetupHandler
  429. bra USBCtrlTrfOutHandler
  430. USBCtrlEPService1
  431. movlw EP00_IN
  432. cpfseq USTAT
  433. return
  434. bra USBCtrlTrfInHandler
  437. ; From usbctrltrf.c line 133
  438. ;/******************************************************************************
  439. ; * Function:        void USBCtrlTrfSetupHandler(void)
  440. ; *
  441. ; * PreCondition:    SetupPkt buffer is loaded with valid USB Setup Data
  442. ; *
  443. ; * Input:           None
  444. ; *
  445. ; * Output:          None
  446. ; *
  447. ; * Side Effects:    None
  448. ; *
  449. ; * Overview:        This routine is a task dispatcher and has 3 stages.
  450. ; *                  1. It initializes the control transfer state machine.
  451. ; *                  2. It calls on each of the module that may know how to
  452. ; *                     service the Setup Request from the host.
  453. ; *                     Module Example: USB9, HID, CDC, MSD, ...
  454. ; *                     As new classes are added, ClassReqHandler table in
  455. ; *                     usbdsc.c should be updated to call all available
  456. ; *                     class handlers.
  457. ; *                  3. Once each of the modules has had a chance to check if
  458. ; *                     it is responsible for servicing the request, stage 3
  459. ; *                     then checks direction of the transfer to determine how
  460. ; *                     to prepare EP0 for the control transfer.
  461. ; *                     Refer to USBCtrlEPServiceComplete() for more details.
  462. ; *
  463. ; * Note:            Microchip USB Firmware has three different states for
  464. ; *                  the control transfer state machine:
  465. ; *                  1. WAIT_SETUP
  466. ; *                  2. CTRL_TRF_TX
  467. ; *                  3. CTRL_TRF_RX
  468. ; *                  Refer to firmware manual to find out how one state
  469. ; *                  is transitioned to another.
  470. ; *
  471. ; *                  A Control Transfer is composed of many USB transactions.
  472. ; *                  When transferring data over multiple transactions,
  473. ; *                  it is important to keep track of data source, data
  474. ; *                  destination, and data count. These three parameters are
  475. ; *                  stored in pSrc,pDst, and wCount. A flag is used to
  476. ; *                  note if the data source is from ROM or RAM.
  477. ; *
  478. ; *****************************************************************************/
  479. USBCtrlTrfSetupHandler
  480. ; movlb high 0x400 ; Point to proper bank
  481. movlw WAIT_SETUP
  482. movwf ctrl_trf_state
  483. movlw MUID_NULL ; Set owner to NULL
  484. movwf ctrl_trf_session_owner
  485. clrf wCount
  486. clrf wCount + 1
  487. rcall USBCheckStdRequest
  488. movlw MUID_NULL
  489. cpfseq ctrl_trf_session_owner
  490. bra USBCtrlEPServiceComplete
  491. #ifdef USB_USE_HID
  492. rcall USBCheckHIDRequest
  493. #endif ; USB_USE_HID
  494. #ifdef USB_USE_CDC
  495. rcall USBCheckCDCRequest
  496. #endif ; USB_USE_CDC
  497. bra USBCtrlEPServiceComplete
  500. ; From usbctrltrf.c line 176
  501. ;/******************************************************************************
  502. ; * Function:        void USBCtrlTrfOutHandler(void)
  503. ; *
  504. ; * PreCondition:    None
  505. ; *
  506. ; * Input:           None
  507. ; *
  508. ; * Output:          None
  509. ; *
  510. ; * Side Effects:    None
  511. ; *
  512. ; * Overview:        This routine handles an OUT transaction according to
  513. ; *                  which control transfer state is currently active.
  514. ; *
  515. ; * Note:            Note that if the the control transfer was from
  516. ; *                  host to device, the session owner should be notified
  517. ; *                  at the end of each OUT transaction to service the
  518. ; *                  received data.
  519. ; *
  520. ; *****************************************************************************/
  521. USBCtrlTrfOutHandler
  522. ; movlb high 0x400 ; Point to proper bank
  523. movlw CTRL_TRF_RX
  524. cpfseq ctrl_trf_state
  525. bra USBPrepareForNextSetupTrf
  526. rcall USBCtrlTrfRxService
  527. movlw _USIE|_DAT1|_DTSEN
  528. btfsc ep0Bo + Stat, DTS
  529. movlw _USIE|_DAT0|_DTSEN
  530. movwf ep0Bo + Stat
  531. return
  534. ; From usbctrltrf.c line 221
  535. ;/******************************************************************************
  536. ; * Function:        void USBCtrlTrfInHandler(void)
  537. ; *
  538. ; * PreCondition:    None
  539. ; *
  540. ; * Input:           None
  541. ; *
  542. ; * Output:          None
  543. ; *
  544. ; * Side Effects:    None
  545. ; *
  546. ; * Overview:        This routine handles an IN transaction according to
  547. ; *                  which control transfer state is currently active.
  548. ; *
  549. ; *
  550. ; * Note:            A Set Address Request must not change the acutal address
  551. ; *                  of the device until the completion of the control
  552. ; *                  transfer. The end of the control transfer for Set Address
  553. ; *                  Request is an IN transaction. Therefore it is necessary
  554. ; *                  to service this unique situation when the condition is
  555. ; *                  right. Macro mUSBCheckAdrPendingState is defined in
  556. ; *                  usb9.h and its function is to specifically service this
  557. ; *                  event.
  558. ; *****************************************************************************/
  559. USBCtrlTrfInHandler
  560. ; movlb high 0x400 ; Point to proper bank
  561. movlw ADR_PENDING_STATE ; Must check if in ADR_PENDING_STATE
  562. cpfseq usb_device_state
  563. bra USBCtrlTrfInHandler1
  564. movf SetupPkt + bDevADR, W
  565. movwf UADDR
  566. movlw ADDRESS_STATE ; If UADDR > 0
  567. btfsc STATUS, Z
  568. movlw DEFAULT_STATE
  569. movwf usb_device_state
  570. USBCtrlTrfInHandler1
  571. movlw CTRL_TRF_TX
  572. cpfseq ctrl_trf_state
  573. bra USBPrepareForNextSetupTrf
  574. rcall USBCtrlTrfTxService
  575. movlw _USIE|_DAT1|_DTSEN
  576. btfsc ep0Bi + Stat, DTS
  577. movlw _USIE|_DAT0|_DTSEN
  578. movwf ep0Bi + Stat
  579. return
  582. ; From usbctrltrf.c line 260
  583. ;/******************************************************************************
  584. ; * Function:        void USBCtrlTrfTxService(void)
  585. ; *
  586. ; * PreCondition:    pSrc, wCount, and usb_stat.ctrl_trf_mem are setup properly.
  587. ; *
  588. ; * Input:           None
  589. ; *
  590. ; * Output:          None
  591. ; *
  592. ; * Side Effects:    None
  593. ; *
  594. ; * Overview:        This routine should be called from only two places.
  595. ; *                  One from USBCtrlEPServiceComplete() and one from
  596. ; *                  USBCtrlTrfInHandler(). It takes care of managing a
  597. ; *                  transfer over multiple USB transactions.
  598. ; *
  599. ; * Note:            Copies one packet-ful of data pSrc (either ROM or RAM) to
  600. ; *                  EP0 IN buffer. It then updates pSrc to be ready for next
  601. ; *                  piece.
  602. ; *                  This routine works with isochronous endpoint larger than
  603. ; *                  256 bytes and is shown here as an example of how to deal
  604. ; *                  with BC9 and BC8. In reality, a control endpoint can never
  605. ; *                  be larger than 64 bytes.
  606. ; *****************************************************************************/
  607. USBCtrlTrfTxService
  608. ; movlb high 0x400 ; Point to proper bank
  609. movf wCount, W ; Preset wCount bytes to send
  610. movwf usb_temp
  611. movf wCount + 1, W
  612. movwf usb_temp + 1
  613. sublw high EP0_BUFF_SIZE ; Make sure count does not exceed maximium length
  614. bnc USBCtrlTrfTxServiceCopy
  615. bnz USBCtrlTrfTxServiceSub
  616. movf wCount, W
  617. sublw low EP0_BUFF_SIZE
  618. bc USBCtrlTrfTxServiceSub
  619. USBCtrlTrfTxServiceCopy
  620. movlw low EP0_BUFF_SIZE ; Send buffer full of bytes
  621. movwf usb_temp
  622. movlw high EP0_BUFF_SIZE
  623. movwf usb_temp + 1
  624. USBCtrlTrfTxServiceSub
  625. movf usb_temp, W ; Subtract actual bytes to be sent from the buffer
  626. movwf ep0Bi + Cnt ; Save low number of bytes to send while we're here
  627. subwf wCount, F
  628. movf usb_temp + 1, W
  629. subwfb wCount + 1, F
  630. movf ep0Bi + Stat, W ; Get full Stat byte
  631. andlw 0xfc ; Clear bottom bits
  632. iorwf usb_temp + 1, W ; Put in high bits of bytes to send
  633. movwf ep0Bi + Stat ; Save it out
  634. lfsr 2, CtrlTrfData ; Set destination pointer
  635. movf usb_temp + 1, W ; Check high byte for 0
  636. bnz USBCtrlTrfTxServiceRomRam ; High byte not 0, must have something to do
  637. movf usb_temp, W ; Check low byte for 0
  638. bz USBCtrlTrfTxServiceExit ; If both 0 then nothing to send this time
  639. USBCtrlTrfTxServiceRomRam
  640. btfss usb_stat, ctrl_trf_mem ; ROM or RAM?
  641. bra USBCtrlTrfTxServiceRam ; RAM
  642. movff pSrc, TBLPTRL ; Move source pointer to TBLPTR
  643. movff pSrc + 1, TBLPTRH
  644. clrf TBLPTRU
  645. USBCtrlTrfTxServiceRomLoop
  646. tblrd *+
  647. movff TABLAT, POSTINC2 ; Copy one buffer to the other
  648. tblrd *+ ; Skip high location
  649. decf usb_temp, F ; Count down number of bytes
  650. bnz USBCtrlTrfTxServiceRomLoop
  651. decf usb_temp + 1, F
  652. bc USBCtrlTrfTxServiceRomLoop
  653. movff TBLPTRL, pSrc ; Update source pointer
  654. movff TBLPTRH, pSrc + 1
  655. return
  656. USBCtrlTrfTxServiceRam
  657. movff pSrc, FSR1L ; Move source pointer to FSR1
  658. movff pSrc + 1, FSR1H
  659. USBCtrlTrfTxServiceRamLoop
  660. movff POSTINC1, POSTINC2 ; Copy one buffer to the other
  661. decf usb_temp, F ; Count down number of bytes
  662. bnz USBCtrlTrfTxServiceRamLoop
  663. decf usb_temp + 1, F
  664. bc USBCtrlTrfTxServiceRamLoop
  665. movff FSR1L, pSrc ; Update source pointer
  666. movff FSR1H, pSrc + 1
  667. USBCtrlTrfTxServiceExit
  668. return
  671. ; From usbctrltrf.c line 330
  672. ;/******************************************************************************
  673. ; * Function:        void USBCtrlTrfRxService(void)
  674. ; *
  675. ; * PreCondition:    pDst and wCount are setup properly.
  676. ; *                  pSrc is always &CtrlTrfData
  677. ; *                  usb_stat.ctrl_trf_mem is always _RAM.
  678. ; *                  wCount should be set to 0 at the start of each control
  679. ; *                  transfer.
  680. ; *
  681. ; * Input:           None
  682. ; *
  683. ; * Output:          None
  684. ; *
  685. ; * Side Effects:    None
  686. ; *
  687. ; * Overview:        Transfers bytes received, at EP0 OUT buffer CtrlTrfData,
  688. ; *                  to user's buffer pointed by pDst.
  689. ; *                  This routine only knows how to handle raw byte data.
  690. ; *                  HIDmaker handles transferring and unpacking by a callback
  691. ; *                  function in the generated main program, called from here.
  692. ; *
  693. ; * Note:            None
  694. ; *****************************************************************************/
  695. USBCtrlTrfRxService
  696. ; movlb high 0x400 ; Point to proper bank
  697. movf ep0Bo + Cnt, W ; Get low number of bytes to read
  698. movwf usb_temp ; usb_temp & usb_temp + 1 are bytes to read
  699. addwf wCount, F ; Accumulate total number of bytes read
  700. movf ep0Bo + Stat, W ; Get high bits to read
  701. andlw 0x03 ; Mask to the count
  702. movwf usb_temp + 1 ; Save to high byte of bytes to read
  703. addwfc wCount + 1, F ; Add overflow from low byte (C) and high byte to total number
  704. lfsr 1, CtrlTrfData ; Point FSR1 to source
  705. movff pDst, FSR2L ; Move destination pointer to FSR2
  706. movff pDst + 1, FSR2H
  707. movf usb_temp + 1, W ; Check high byte for 0
  708. bnz USBCtrlTrfRxServiceLoop ; High byte not 0, must have something to do
  709. movf usb_temp, W ; Check low byte for 0
  710. bz USBCtrlTrfRxServiceExit ; If both 0 then nothing to send this time
  711. USBCtrlTrfRxServiceLoop
  712. movff POSTINC1, POSTINC2 ; Copy one buffer to the other
  713. decf usb_temp, F ; Count down number of bytes
  714. bnz USBCtrlTrfRxServiceLoop
  715. decf usb_temp + 1, F
  716. bc USBCtrlTrfRxServiceLoop
  717. movff FSR2L, pDst ; Update destination pointer
  718. movff FSR2H, pDst + 1
  719. USBCtrlTrfRxServiceExit
  720. return
  723. ; From usbctrltrf.c line 382
  724. ;/******************************************************************************
  725. ; * Function:        void USBCtrlEPServiceComplete(void)
  726. ; *
  727. ; * PreCondition:    None
  728. ; *
  729. ; * Input:           None
  730. ; *
  731. ; * Output:          None
  732. ; *
  733. ; * Side Effects:    None
  734. ; *
  735. ; * Overview:        This routine wrap up the ramaining tasks in servicing
  736. ; *                  a Setup Request. Its main task is to set the endpoint
  737. ; *                  controls appropriately for a given situation. See code
  738. ; *                  below.
  739. ; *                  There are three main scenarios:
  740. ; *                  a) There was no handler for the Request, in this case
  741. ; *                     a STALL should be sent out.
  742. ; *                  b) The host has requested a read control transfer,
  743. ; *                     endpoints are required to be setup in a specific way.
  744. ; *                  c) The host has requested a write control transfer, or
  745. ; *                     a control data stage is not required, endpoints are
  746. ; *                     required to be setup in a specific way.
  747. ; *
  748. ; *                  Packet processing is resumed by clearing PKTDIS bit.
  749. ; *
  750. ; * Note:            None
  751. ; *****************************************************************************/
  752. USBCtrlEPServiceComplete
  753. ; movlb high 0x400 ; Point to proper bank
  754. movlw MUID_NULL
  755. cpfseq ctrl_trf_session_owner
  756. bra USBCtrlEPServiceComplete1
  757. ;
  758. ; No handlers claimed ownership of this Setup packet.
  759. ; If no one knows how to service this request then stall.
  760. ; Must also prepare EP0 to receive the next SETUP transaction.
  761. movlw EP0_BUFF_SIZE
  762. movwf ep0Bo + Cnt
  763. movlw low SetupPkt
  764. movwf ep0Bo + ADRL
  765. movlw high SetupPkt
  766. movwf ep0Bo + ADRH
  767. movlw _USIE|_BSTALL
  768. movwf ep0Bo + Stat
  769. ; movlw _USIE|_BSTALL
  770. movwf ep0Bi + Stat
  771. bra USBCtrlEPServiceCompleteExit
  772. ;
  773. ; A module has claimed ownership of the control transfer session.
  774. USBCtrlEPServiceComplete1
  775. btfss SetupPkt, DataDir
  776. bra USBCtrlEPServiceComplete2
  777. movf wCount + 1, W ; Make sure count does not exceed max length requested by Host
  778. subwf SetupPkt + wLength + 1, W
  779. bnc USBCtrlEPServiceCompleteCopy
  780. bnz USBCtrlEPServiceComplete11
  781. movf wCount, W
  782. subwf SetupPkt + wLength, W
  783. bc USBCtrlEPServiceComplete11
  784. USBCtrlEPServiceCompleteCopy
  785. movff SetupPkt + wLength, wCount ; Set count to maximum
  786. movff SetupPkt + wLength + 1, wCount + 1
  787. ;
  788. ; Setup packet's data direction is "Device to Host"
  789. USBCtrlEPServiceComplete11
  790. rcall USBCtrlTrfTxService    ; Actually copy the data to EP0 IN buffer
  791. movlw CTRL_TRF_TX
  792. movwf ctrl_trf_state
  793. ; Control Read:
  794. ; <SETUP[0]><IN[1]><IN[0]>...<OUT[1]> | <SETUP[0]>
  795. ; 1. Prepare OUT EP to respond to early termination
  796. ;
  797. ; NOTE:
  798. ; If something went wrong during the control transfer,
  799. ; the last status stage may not be sent by the host.
  800. ; When this happens, two different things could happen
  801. ; depending on the host.
  802. ; a) The host could send out a RESET.
  803. ; b) The host could send out a new SETUP transaction
  804. ;    without sending a RESET first.
  805. ; To properly handle case (b), the OUT EP must be setup
  806. ; to receive either a zero length OUT transaction, or a
  807. ; new SETUP transaction.
  808. ;
  809. ; Since the SETUP transaction requires the DTS bit to be
  810. ; DAT0 while the zero length OUT status requires the DTS
  811. ; bit to be DAT1, the DTS bit check by the hardware should
  812. ; be disabled. This way the SIE could accept either of
  813. ; the two transactions.
  814. ;
  815. ; Furthermore, the Cnt byte should be set to prepare for
  816. ; the SETUP data (8-byte or more), and the buffer address
  817. ; should be pointed to SetupPkt.
  818. movlw EP0_BUFF_SIZE
  819. movwf ep0Bo + Cnt
  820. movlw low SetupPkt
  821. movwf ep0Bo + ADRL
  822. movlw high SetupPkt
  823. movwf ep0Bo + ADRH
  824. movlw _USIE ; Note: DTSEN is 0!
  825. movwf ep0Bo + Stat
  826. ; 2. Prepare IN EP to transfer data, Cnt should have
  827. ;    been initialized by responsible request owner.
  828. movlw low CtrlTrfData
  829. movwf ep0Bi + ADRL
  830. movlw high CtrlTrfData
  831. movwf ep0Bi + ADRH
  832. movlw _USIE|_DAT1|_DTSEN
  833. movwf ep0Bi + Stat
  834. bra USBCtrlEPServiceCompleteExit
  835. ;
  836. ; Setup packet's data direction is "Host to Device"
  837. USBCtrlEPServiceComplete2
  838. movlw CTRL_TRF_RX
  839. movwf ctrl_trf_state
  840. ; Control Write:
  841. ; <SETUP[0]><OUT[1]><OUT[0]>...<IN[1]> | <SETUP[0]>
  842. ;
  843. ; 1. Prepare IN EP to respond to early termination
  844. ;
  845. ;    This is the same as a Zero Length Packet Response
  846. ;    for control transfer without a data stage
  847. clrf ep0Bi + Cnt
  848. movlw _USIE|_DAT1|_DTSEN
  849. movwf ep0Bi + Stat
  850. ; 2. Prepare OUT EP to receive data.
  851. movlw EP0_BUFF_SIZE
  852. movwf ep0Bo + Cnt
  853. movlw low CtrlTrfData
  854. movwf ep0Bo + ADRL
  855. movlw high CtrlTrfData
  856. movwf ep0Bo + ADRH
  857. movlw _USIE|_DAT1|_DTSEN
  858. movwf ep0Bo + Stat
  859. ;
  860. USBCtrlEPServiceCompleteExit
  861. ; PKTDIS bit is set when a Setup Transaction is received.
  862. ; Clear to resume packet processing.
  863. bcf UCON, PKTDIS
  864. return
  867. ; From usbctrltrf.c line 490
  868. ;/******************************************************************************
  869. ; * Function:        void USBPrepareForNextSetupTrf(void)
  870. ; *
  871. ; * PreCondition:    None
  872. ; *
  873. ; * Input:           None
  874. ; *
  875. ; * Output:          None
  876. ; *
  877. ; * Side Effects:    None
  878. ; *
  879. ; * Overview:        The routine forces EP0 OUT to be ready for a new Setup
  880. ; *                  transaction, and forces EP0 IN to be owned by CPU.
  881. ; *
  882. ; * Note:            None
  883. ; *****************************************************************************/
  884. USBPrepareForNextSetupTrf
  885. ; movlb high 0x400 ; Point to proper bank
  886. movlw WAIT_SETUP
  887. movwf ctrl_trf_state
  888. movlw EP0_BUFF_SIZE
  889. movwf ep0Bo + Cnt
  890. movlw low SetupPkt
  891. movwf ep0Bo + ADRL
  892. movlw high SetupPkt
  893. movwf ep0Bo + ADRH
  894. movlw _USIE|_DAT0|_DTSEN ; EP0 buff dsc init
  895. movwf ep0Bo + Stat
  896. movlw _UCPU ; EP0 IN buffer initialization
  897. movwf ep0Bi + Stat
  898. return
  902. ; From usbdrv.c line ???
  903. ;/******************************************************************************
  904. ; * Function:        void InitializeUSBDriver(void)
  905. ; *
  906. ; * PreCondition:    None
  907. ; *
  908. ; * Input:           None
  909. ; *
  910. ; * Output:          None
  911. ; *
  912. ; * Side Effects:    None
  913. ; *
  914. ; * Overview:        This routine initializes variables used by the USB library
  915. ; *                  routines.
  916. ; *
  917. ; * Note:            None
  918. ; *****************************************************************************/
  919. InitializeUSBDriver
  920. movlb high 0x400 ; Point to proper bank
  921. movlw UCFG_VAL
  922. movwf UCFG
  923. movlw DETACHED_STATE
  924. movwf usb_device_state
  925. clrf usb_stat
  926. clrf usb_active_cfg
  927. #ifdef USB_USE_HID
  928. rcall HIDInitEP
  929. #endif
  930. #ifdef USB_USE_CDC
  931. rcall CDCInitEP
  932. #endif
  933. return
  936. ; From usbdrv.c line 76
  937. ;/******************************************************************************
  938. ; * Function:        void USBCheckBusStatus(void)
  939. ; *
  940. ; * PreCondition:    None
  941. ; *
  942. ; * Input:           None
  943. ; *
  944. ; * Output:          None
  945. ; *
  946. ; * Side Effects:    None
  947. ; *
  948. ; * Overview:        This routine enables/disables the USB module by monitoring
  949. ; *                  the USB power signal.
  950. ; *
  951. ; * Note:            None
  952. ; *****************************************************************************/
  953. USBCheckBusStatus
  954. movlb high 0x400 ; Point to proper bank
  955. ; Bus Attachment & Detachment Detection
  956. ; usb_bus_sense is an i/o pin defined in io_cfg.h
  957. #ifdef USE_USB_BUS_SENSE_IO
  958. btfss usb_bus_sense ; Is USB bus attached?
  959. bra USBCheckBusStatusDetached ; No
  960. #endif
  961. btfss UCON, USBEN ; Is the module off?
  962. rcall USBModuleEnable ; Is off, enable it
  963. #ifdef USE_USB_BUS_SENSE_IO
  964. bra USBCheckBusStatus1
  965. USBCheckBusStatusDetached
  966. btfsc UCON, USBEN ; Is the module on?
  967. rcall USBModuleDisable ; Is on, disable it
  968. #endif
  969. ;
  970. ; After enabling the USB module, it takes some time for the voltage
  971. ; on the D+ or D- line to rise high enough to get out of the SE0 condition.
  972. ; The USB Reset interrupt should not be unmasked until the SE0 condition is
  973. ; cleared. This helps preventing the firmware from misinterpreting this
  974. ; unique event as a USB bus reset from the USB host.
  975. USBCheckBusStatus1
  976. movlw ATTACHED_STATE
  977. cpfseq usb_device_state
  978. return
  979. btfsc UCON, SE0
  980. return
  981. clrf UIR ; Clear all USB interrupts
  982. clrf UIE ; Mask all USB interrupts
  983. bsf UIE, URSTIE ; Unmask RESET interrupt
  984. bsf UIE, IDLEIE ; Unmask IDLE interrupt
  985. movlw POWERED_STATE
  986. movwf usb_device_state
  987. return
  990. ; From usbdrv.c line 135
  991. USBModuleEnable
  992. ; movlb high 0x400 ; Point to proper bank
  993. clrf UCON
  994. clrf UIE ; Mask all USB interrupts
  995. bsf UCON, USBEN ; Enable module & attach to bus
  996. movlw ATTACHED_STATE
  997. movwf usb_device_state
  998. return
  1001. ; From usbdrv.c line 192
  1002. USBSoftDetach
  1003. ; From usbdrv.c line 161
  1004. USBModuleDisable
  1005. movlb high 0x400 ; Point to proper bank
  1006. clrf UCON ; Disable module & detach from bus
  1007. clrf UIE ; Mask all USB interrupts
  1008. movlw DETACHED_STATE
  1009. movwf usb_device_state
  1010. return
  1013. ; From usbdrv.c line 215
  1014. ;/******************************************************************************
  1015. ; * Function:        void USBDriverService(void)
  1016. ; *
  1017. ; * PreCondition:    None
  1018. ; *
  1019. ; * Input:           None
  1020. ; *
  1021. ; * Output:          None
  1022. ; *
  1023. ; * Side Effects:    None
  1024. ; *
  1025. ; * Overview:        This routine is the heart of this firmware. It manages
  1026. ; *                  all USB interrupts.
  1027. ; *
  1028. ; * Note:            Device state transitions through the following stages:
  1029. ; *                  DETACHED -> ATTACHED -> POWERED -> DEFAULT ->
  1030. ; *                  ADDRESS_PENDING -> ADDRESSED -> CONFIGURED -> READY
  1031. ; *****************************************************************************/
  1032. USBDriverService
  1033. movlb high 0x400 ; Point to proper bank
  1034. movlw DETACHED_STATE
  1035. subwf usb_device_state, W
  1036. bz USBDriverServiceExit ; Pointless to continue servicing
  1037. ; if USB cable is not even attached.
  1038. ;
  1039. ; Task A: Service USB Activity Interrupt
  1040. btfss UIR, ACTVIF
  1041. bra USBDriverService1
  1042. btfsc UIE, ACTVIE
  1043. rcall USBWakeFromSuspend
  1044. ;
  1045. USBDriverService1
  1046. btfsc UCON, SUSPND ; Are we suspended?
  1047. return ; Pointless to continue servicing if the device is in suspend mode.
  1048. ;
  1049. ; Task B: Service USB Bus Reset Interrupt.
  1050. ; When bus reset is received during suspend, ACTVIF will be set first,
  1051. ; once the UCONbits.SUSPND is clear, then the URSTIF bit will be asserted.
  1052. ; This is why URSTIF is checked after ACTVIF.
  1053. ;
  1054. ; The USB reset flag is masked when the USB state is in
  1055. ; DETACHED_STATE or ATTACHED_STATE, and therefore cannot
  1056. ; cause a USB reset event during these two states.
  1057. btfss UIR, URSTIF        ; USB Bus Reset Interrupt?
  1058. bra USBDriverService2
  1059. btfsc UIE, URSTIE
  1060. rcall USBProtocolResetHandler
  1061. ;
  1062. ; Task C: Check & service other USB interrupts
  1063. USBDriverService2
  1064. btfss UIR, IDLEIF
  1065. bra USBDriverService3
  1066. btfsc UIE, IDLEIE
  1067. rcall USBSuspend
  1068. USBDriverService3
  1069. btfss UIR, SOFIF
  1070. bra USBDriverService4
  1071. btfsc UIE, SOFIE
  1072. rcall USB_SOF_Handler
  1073. USBDriverService4
  1074. btfss UIR, STALLIF
  1075. bra USBDriverService5
  1076. btfsc UIE, STALLIE
  1077. rcall USBStallHandler
  1078. USBDriverService5
  1079. btfss UIR, UERRIF
  1080. bra USBDriverService6
  1081. btfsc UIE, UERRIE
  1082. rcall USBErrorHandler
  1083. ;
  1084. ; Pointless to continue servicing if the host has not sent a bus reset.
  1085. ; Once bus reset is received, the device transitions into the DEFAULT
  1086. ;     * state and is ready for communication.
  1087. USBDriverService6
  1088. movlw DEFAULT_STATE
  1089. subwf usb_device_state, W
  1090. bnc USBDriverServiceExit
  1091. ;
  1092. ; Task D: Servicing USB Transaction Complete Interrupt
  1093. btfss UIR, TRNIF
  1094. bra USBDriverServiceExit
  1095. btfss UIE, TRNIE
  1096. bra USBDriverServiceExit
  1097. ;
  1098. ; USBCtrlEPService only services transactions over EP0.
  1099. ; It ignores all other EP transactions.
  1100. rcall USBCtrlEPService
  1101. ; Other EPs can be serviced later by responsible device class firmware.
  1102. ; Each device driver knows when an OUT or IN transaction is ready by
  1103. ; checking the buffer ownership bit.
  1104. ; An OUT EP should always be owned by SIE until the data is ready.
  1105. ; An IN EP should always be owned by CPU until the data is ready.
  1106. ;
  1107. ; Because of this logic, it is not necessary to save the USTAT value
  1108. ; of non-EP0 transactions.
  1109. bcf UIR, TRNIF
  1110. USBDriverServiceExit
  1111. return
  1114. ; From usbdrv.c line 301
  1115. ;/******************************************************************************
  1116. ; * Function:        void USBSuspend(void)
  1117. ; *
  1118. ; * PreCondition:    None
  1119. ; *
  1120. ; * Input:           None
  1121. ; *
  1122. ; * Output:          None
  1123. ; *
  1124. ; * Side Effects:    None
  1125. ; *
  1126. ; * Overview:
  1127. ; *
  1128. ; * Note:            None
  1129. ; *****************************************************************************/
  1130. USBSuspend
  1131. ; NOTE: Do not clear UIRbits.ACTVIF here!
  1132. ; Reason:
  1133. ; ACTVIF is only generated once an IDLEIF has been generated.
  1134. ; This is a 1:1 ratio interrupt generation.
  1135. ; For every IDLEIF, there will be only one ACTVIF regardless of
  1136. ; the number of subsequent bus transitions.
  1137. ;
  1138. ; If the ACTIF is cleared here, a problem could occur when:
  1139. ; [       IDLE       ][bus activity ->
  1140. ; <--- 3 ms ----->     ^
  1141. ;                ^     ACTVIF=1
  1142. ;                IDLEIF=1
  1143. ;  #           #           #           #   (#=Program polling flags)
  1144. ;                          ^
  1145. ;                          This polling loop will see both
  1146. ;                          IDLEIF=1 and ACTVIF=1.
  1147. ;                          However, the program services IDLEIF first
  1148. ;                          because ACTIVIE=0.
  1149. ;                          If this routine clears the only ACTIVIF,
  1150. ;                          then it can never get out of the suspend
  1151. ;                          mode.
  1152. bsf UIE, ACTVIE ; Enable bus activity interrupt
  1153. bcf UIR, IDLEIF
  1154. bsf UCON, SUSPND ; Put USB module in power conserve
  1155. ; At this point the PIC can go into sleep,idle, or
  1156. ; switch to a slower clock, etc.
  1157. return
  1160. ; From usbdrv.c line 353
  1161. ;/******************************************************************************
  1162. ; * Function:        void USBWakeFromSuspend(void)
  1163. ; *
  1164. ; * PreCondition:    None
  1165. ; *
  1166. ; * Input:           None
  1167. ; *
  1168. ; * Output:          None
  1169. ; *
  1170. ; * Side Effects:    None
  1171. ; *
  1172. ; * Overview:
  1173. ; *
  1174. ; * Note:            None
  1175. ; *****************************************************************************/
  1176. USBWakeFromSuspend
  1177. ; If using clock switching, this is the place to restore the
  1178. ; original clock frequency.
  1179. bcf UCON, SUSPND
  1180. bcf UIE, ACTVIE
  1181. bcf UIR, ACTVIF
  1182. return
  1185. ; From usbdrv.c line 402
  1186. ;/******************************************************************************
  1187. ; * Function:        void USBRemoteWakeup(void)
  1188. ; *
  1189. ; * PreCondition:    None
  1190. ; *
  1191. ; * Input:           None
  1192. ; *
  1193. ; * Output:          None
  1194. ; *
  1195. ; * Side Effects:    None
  1196. ; *
  1197. ; * Overview:        This function should be called by user when the device
  1198. ; *                  is waken up by an external stimulus other than ACTIVIF.
  1199. ; *                  Please read the note below to understand the limitations.
  1200. ; *
  1201. ; * Note:            The modifiable section in this routine should be changed
  1202. ; *                  to meet the application needs. Current implementation
  1203. ; *                  temporary blocks other functions from executing for a
  1204. ; *                  period of 1-13 ms depending on the core frequency.
  1205. ; *
  1206. ; *                  According to USB 2.0 specification section 7.1.7.7,
  1207. ; *                  "The remote wakeup device must hold the resume signaling
  1208. ; *                  for at lest 1 ms but for no more than 15 ms."
  1209. ; *                  The idea here is to use a delay counter loop, using a
  1210. ; *                  common value that would work over a wide range of core
  1211. ; *                  frequencies.
  1212. ; *                  That value selected is 1800. See table below:
  1213. ; *                  ==========================================================
  1214. ; *                  Core Freq(MHz)      MIP         RESUME Signal Period (ms)
  1215. ; *                  ==========================================================
  1216. ; *                      48              12          1.05
  1217. ; *                       4              1           12.6
  1218. ; *                  ==========================================================
  1219. ; *                  * These timing could be incorrect when using code
  1220. ; *                    optimization or extended instruction mode,
  1221. ; *                    or when having other interrupts enabled.
  1222. ; *                    Make sure to verify using the MPLAB SIM's Stopwatch
  1223. ; *****************************************************************************/
  1224. USBRemoteWakeup
  1225. movlb high 0x400 ; Point to proper bank
  1226. btfss usb_stat, RemoteWakeup ; Check if RemoteWakeup function has been enabled by the host.
  1227. return ; No
  1228. rcall USBWakeFromSuspend ; Unsuspend USB modue
  1229. bsf UCON, RESUME ; Start RESUME signaling
  1230. movlw 0x10 ; Set RESUME line for 1-13 ms
  1231. movwf FSR2H ; Using FSR2 as temp
  1232. clrf FSR2L
  1233. USBRemoteWakeupLoop
  1234. decfsz FSR2L, F
  1235. bra USBRemoteWakeupLoop
  1236. decfsz FSR2H, F
  1237. bra USBRemoteWakeupLoop
  1238. bcf UCON, RESUME
  1239. return
  1242. ; From usbdrv.c line 443
  1243. ;/******************************************************************************
  1244. ; * Function:        void USB_SOF_Handler(void)
  1245. ; *
  1246. ; * PreCondition:    None
  1247. ; *
  1248. ; * Input:           None
  1249. ; *
  1250. ; * Output:          None
  1251. ; *
  1252. ; * Side Effects:    None
  1253. ; *
  1254. ; * Overview:        The USB host sends out a SOF packet to full-speed devices
  1255. ; *                  every 1 ms. This interrupt may be useful for isochronous
  1256. ; *                  pipes. End designers should implement callback routine
  1257. ; *                  as necessary.
  1258. ; *
  1259. ; * Note:            None
  1260. ; *****************************************************************************/
  1261. USB_SOF_Handler
  1262. ; Callback routine here
  1263. bcf UIR, SOFIF
  1264. return
  1267. ; From usbdrv.c line 486
  1268. ;/******************************************************************************
  1269. ; * Function:        void USBStallHandler(void)
  1270. ; *
  1271. ; * PreCondition:    A STALL packet is sent to the host by the SIE.
  1272. ; *
  1273. ; * Input:           None
  1274. ; *
  1275. ; * Output:          None
  1276. ; *
  1277. ; * Side Effects:    None
  1278. ; *
  1279. ; * Overview:        The STALLIF is set anytime the SIE sends out a STALL
  1280. ; *                  packet regardless of which endpoint causes it.
  1281. ; *                  A Setup transaction overrides the STALL function. A stalled
  1282. ; *                  endpoint stops stalling once it receives a setup packet.
  1283. ; *                  In this case, the SIE will accepts the Setup packet and
  1284. ; *                  set the TRNIF flag to notify the firmware. STALL function
  1285. ; *                  for that particular endpoint pipe will be automatically
  1286. ; *                  disabled (direction specific).
  1287. ; *
  1288. ; *                  There are a few reasons for an endpoint to be stalled.
  1289. ; *                  1. When a non-supported USB request is received.
  1290. ; *                     Example: GET_DESCRIPTOR(DEVICE_QUALIFIER)
  1291. ; *                  2. When an endpoint is currently halted.
  1292. ; *                  3. When the device class specifies that an endpoint must
  1293. ; *                     stall in response to a specific event.
  1294. ; *                     Example: Mass Storage Device Class
  1295. ; *                              If the CBW is not valid, the device shall
  1296. ; *                              STALL the Bulk-In pipe.
  1297. ; *                              See USB Mass Storage Class Bulk-only Transport
  1298. ; *                              Specification for more details.
  1299. ; *
  1300. ; * Note:            UEPn.EPSTALL can be scanned to see which endpoint causes
  1301. ; *                  the stall event.
  1302. ; *                  If
  1303. ; *****************************************************************************/
  1304. USBStallHandler
  1305. ; Does not really have to do anything here,
  1306. ; even for the control endpoint.
  1307. ; All BDs of Endpoint 0 are owned by SIE right now,
  1308. ; but once a Setup Transaction is received, the ownership
  1309. ; for EP0_OUT will be returned to CPU.
  1310. ; When the Setup Transaction is serviced, the ownership
  1311. ; for EP0_IN will then be forced back to CPU by firmware.
  1312. ;
  1313. ; NOTE: Above description is not quite true at this point.
  1314. ;       It seems the SIE never returns the UOWN bit to CPU,
  1315. ;       and a TRNIF is never generated upon successful
  1316. ;       reception of a SETUP transaction.
  1317. ;       Firmware work-around is implemented below.
  1318. ;
  1319. btfsc UEP0, EPSTALL
  1320. rcall USBPrepareForNextSetupTrf ; Firmware Work-Around
  1321. bcf UEP0, EPSTALL
  1322. bcf UIR, STALLIF
  1323. return
  1325. ; From usbdrv.c line 528
  1326. ;/******************************************************************************
  1327. ; * Function:        void USBErrorHandler(void)
  1328. ; *
  1329. ; * PreCondition:    None
  1330. ; *
  1331. ; * Input:           None
  1332. ; *
  1333. ; * Output:          None
  1334. ; *
  1335. ; * Side Effects:    None
  1336. ; *
  1337. ; * Overview:        The purpose of this interrupt is mainly for debugging
  1338. ; *                  during development. Check UEIR to see which error causes
  1339. ; *                  the interrupt.
  1340. ; *
  1341. ; * Note:            None
  1342. ; *****************************************************************************/
  1343. USBErrorHandler
  1344. bcf UIR, UERRIF
  1345. return
  1348. ; From usbdrv.c line 555
  1349. ;/******************************************************************************
  1350. ; * Function:        void USBProtocolResetHandler(void)
  1351. ; *
  1352. ; * PreCondition:    A USB bus reset is received from the host.
  1353. ; *
  1354. ; * Input:           None
  1355. ; *
  1356. ; * Output:          None
  1357. ; *
  1358. ; * Side Effects:    Currently, this routine flushes any pending USB
  1359. ; *                  transactions. It empties out the USTAT FIFO. This action
  1360. ; *                  might not be desirable in some applications.
  1361. ; *
  1362. ; * Overview:        Once a USB bus reset is received from the host, this
  1363. ; *                  routine should be called. It resets the device address to
  1364. ; *                  zero, disables all non-EP0 endpoints, initializes EP0 to
  1365. ; *                  be ready for default communication, clears all USB
  1366. ; *                  interrupt flags, unmasks applicable USB interrupts, and
  1367. ; *                  reinitializes internal state-machine variables.
  1368. ; *
  1369. ; * Note:            None
  1370. ; *****************************************************************************/
  1371. USBProtocolResetHandler
  1372. ; movlb high 0x400 ; Point to proper bank
  1373. clrf UEIR ; Clear all USB error flags
  1374. clrf UIR ; Clears all USB interrupts
  1375. movlw 0x9f ; Unmask all USB error interrupts
  1376. movwf UEIE
  1377. movlw 0x7b ; Enable all interrupts except ACTVIE
  1378. movwf UIE
  1379. clrf UADDR ; Reset to default address
  1380. lfsr 2, UEP1 ; Reset all non-EP0 UEPn registers
  1381. movlw 15
  1382. USBProtocolResetHandlerClearLoop
  1383. clrf POSTINC2
  1384. decfsz WREG, F
  1385. bra USBProtocolResetHandlerClearLoop
  1386. movlw EP_CTRL|HSHK_EN ; Init EP0 as a Ctrl EP
  1387. movwf UEP0
  1388. btfsc UIR, TRNIF ; Flush any pending transactions
  1389. USBProtocolResetHandlerFlushLoop
  1390. bcf UIR, TRNIF
  1391. btfsc UIR, TRNIF
  1392. bra USBProtocolResetHandlerFlushLoop
  1393. bcf UCON, PKTDIS ; Make sure packet processing is enabled
  1394.    rcall USBPrepareForNextSetupTrf
  1395. bcf usb_stat, RemoteWakeup ; Default status flag to disable
  1396. clrf usb_active_cfg ; Clear active configuration
  1397. movlw DEFAULT_STATE
  1398.    movwf usb_device_state
  1399. return
  1403. #ifdef USB_USE_HID
  1405. ; From hid.c  line 72
  1406. ;/******************************************************************************
  1407. ; * Function:        void USBCheckHIDRequest(void)
  1408. ; *
  1409. ; * PreCondition:    None
  1410. ; *
  1411. ; * Input:           None
  1412. ; *
  1413. ; * Output:          None
  1414. ; *
  1415. ; * Side Effects:    None
  1416. ; *
  1417. ; * Overview:        This routine checks the setup data packet to see if it
  1418. ; *                  knows how to handle it
  1419. ; *
  1420. ; * Note:            None
  1421. ; *****************************************************************************/
  1422. USBCheckHIDRequest
  1423. movlb high 0x400 ; Point to proper bank
  1424. movf SetupPkt, W ; Recipient = RCPT_INTF?
  1425. andlw 0x1f ; Mask to lower 5 bits
  1426. sublw RCPT_INTF
  1427. bnz USBCheckHIDRequestExit ; No
  1428. movlw HID_INTF_ID ; IntfID = HID_INTF_ID?
  1429. cpfseq SetupPkt + bIntfID
  1430. USBCheckHIDRequestExit
  1431. return ; No
  1432. ;
  1433. ; There are two standard requests that hid.c may support.
  1434. ; 1. GET_DSC(DSC_HID,DSC_RPT,DSC_PHY);
  1435. ; 2. SET_DSC(DSC_HID,DSC_RPT,DSC_PHY);
  1436. ;
  1437. movlw GET_DSC ; Request = GET_DSC?
  1438. cpfseq SetupPkt + bRequest
  1439. bra USBCheckHIDRequestClass ; No
  1440. movlw DSC_HID ; DscType = DSC_HID?
  1441. cpfseq SetupPkt + bDscType
  1442. bra USBCheckHIDRequest1 ; No
  1443. mSetSourcePointer HIDDescriptor1
  1444. mGetRomTableCount ; Set wCount
  1445. bsf usb_stat, ctrl_trf_mem ; Indicate ROM
  1446. bra USBHIDSetSessionOwner
  1447. USBCheckHIDRequest1
  1448. movlw DSC_RPT ; DscType = DSC_RPT?
  1449. cpfseq SetupPkt + bDscType
  1450. bra USBCheckHIDRequest2 ; No
  1451. mSetSourcePointer ReportDescriptor1
  1452. movlw low (ReportDescriptor1Len) ; Set wCount
  1453. movwf TBLPTRL
  1454. movlw high (ReportDescriptor1Len)
  1455. movwf TBLPTRH
  1456. clrf TBLPTRU
  1457.         tblrd   *+ ; Read count low
  1458. movff TABLAT, wCount
  1459.         tblrd   *+ ; Skip next
  1460.         tblrd   * ; Read count high
  1461. movff TABLAT, wCount + 1
  1462. bsf usb_stat, ctrl_trf_mem ; Indicate ROM
  1463. bra USBHIDSetSessionOwner
  1464. USBCheckHIDRequest2
  1465. ; movlw DSC_PHY ; DscType = DSC_PHY?
  1466. ; cpfseq SetupPkt + bDscType
  1467. ; return ; No
  1468. USBCheckHIDRequestClass
  1469. movf SetupPkt, W ; RequestType = CLASS?
  1470. andlw 0x60 ; Mask to proper bits
  1471. sublw (CLASS) << 5
  1472. bnz USBCheckHIDRequestExit ; No
  1473. ; movlw GET_REPORT ; Request = GET_REPORT?
  1474. ; subwf SetupPkt + bRequest, W
  1475. ; bz HIDGetReportHandler ; Yes
  1476. ; movlw SET_REPORT ; Request = SET_REPORT?
  1477. ; subwf SetupPkt + bRequest, W
  1478. ; bz HIDSetReportHandler ; Yes
  1479. movlw GET_IDLE ; Request = GET_IDLE?
  1480. cpfseq SetupPkt + bRequest
  1481. bra USBCheckHIDRequestClass1 ; No
  1482. mSetSourcePointer idle_rate
  1483. movlw 1
  1484. movwf wCount
  1485. clrf wCount + 1
  1486. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  1487. bra USBHIDSetSessionOwner
  1488. USBCheckHIDRequestClass1
  1489. movlw SET_IDLE ; Request = SET_IDLE?
  1490. cpfseq SetupPkt + bRequest
  1491. bra USBCheckHIDRequestClass2 ; No
  1492. movff SetupPkt + wValue + 1, idle_rate
  1493. bra USBHIDSetSessionOwner
  1494. USBCheckHIDRequestClass2
  1495. movlw GET_PROTOCOL ; Request = GET_PROTOCOL?
  1496. cpfseq SetupPkt + bRequest
  1497. bra USBCheckHIDRequestClass3 ; No
  1498. mSetSourcePointer active_protocol
  1499. movlw 1
  1500. movwf wCount
  1501. clrf wCount + 1
  1502. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  1503. bra USBHIDSetSessionOwner
  1504. USBCheckHIDRequestClass3
  1505. movlw SET_PROTOCOL ; Request = SET_PROTOCOL?
  1506. cpfseq SetupPkt + bRequest
  1507. return ; No
  1508. movff SetupPkt + wValue, active_protocol
  1509. USBHIDSetSessionOwner
  1510. movlw MUID_HID
  1511. movwf ctrl_trf_session_owner
  1512. return
  1515. ; From hid.c  line 158
  1516. ;/******************************************************************************
  1517. ; * Function:        void HIDInitEP(void)
  1518. ; *
  1519. ; * PreCondition:    None
  1520. ; *
  1521. ; * Input:           None
  1522. ; *
  1523. ; * Output:          None
  1524. ; *
  1525. ; * Side Effects:    None
  1526. ; *
  1527. ; * Overview:        HIDInitEP initializes HID endpoints, buffer descriptors,
  1528. ; *                  internal state-machine, and variables.
  1529. ; *                  It should be called after the USB host has sent out a
  1530. ; *                  SET_CONFIGURATION request.
  1531. ; *                  See USBStdSetCfgHandler() in usb9.c for examples.
  1532. ; *
  1533. ; * Note:            None
  1534. ; *****************************************************************************/
  1535. HIDInitEP
  1536. movlw 1 ; Endpoint 1 Out
  1537. movwf FSR0L
  1538. lfsr 1, hid_report_out ; FSR1 = endpoint buffer address
  1539. movlw HID_INT_OUT_EP_SIZE ; W = endpoint size
  1540. rcall InitEPOut ; Inititalize the endpoint
  1542. movlw 1 ; Endpoint 1 In
  1543. movwf FSR0L
  1544. lfsr 1, hid_report_in ; FSR1 = endpoint buffer address
  1545. movlw HID_INT_IN_EP_SIZE ; W = endpoint size
  1546. bra InitEPIn ; Inititalize the endpoint
  1548. #endif ; USB_USE_HID
  1552. #ifdef USB_USE_CDC
  1554. ;/******************************************************************************
  1555. ; * Function:        void USBCheckCDCRequest(void)
  1556. ; *
  1557. ; * PreCondition:    None
  1558. ; *
  1559. ; * Input:           None
  1560. ; *
  1561. ; * Output:          None
  1562. ; *
  1563. ; * Side Effects:    None
  1564. ; *
  1565. ; * Overview:        This routine checks the setup data packet to see if it
  1566. ; *                  knows how to handle it
  1567. ; *
  1568. ; * Note:            None
  1569. ; *****************************************************************************/
  1570. USBCheckCDCRequest
  1571. ;    /*
  1572. ;     * If request recipient is not an interface then return
  1573. ;     */
  1574. movlb high 0x400 ; Point to proper bank
  1575. movf SetupPkt, W ; Recipient = RCPT_INTF?
  1576. andlw 0x1f ; Mask to lower 5 bits
  1577. sublw RCPT_INTF
  1578. bnz USBCheckCDCRequestExit ; No
  1580. ;    /*
  1581. ;     * If request type is not class-specific then return
  1582. ;     */
  1583. movf SetupPkt, W ; RequestType = CLASS?
  1584. andlw 0x60 ; Mask to proper bits
  1585. sublw (CLASS) << 5
  1586. bnz USBCheckCDCRequestExit ; No
  1588. ;    /*
  1589. ;     * Interface ID must match interface numbers associated with
  1590. ;     * CDC class, else return
  1591. ;     */
  1592. movlw CDC_COMM_INTF_ID ; IntfID = CDC_COMM_INTF_ID?
  1593. subwf SetupPkt + bIntfID, W
  1594. bz USBCheckCDCRequest1 ; Yes
  1595. movlw CDC_DATA_INTF_ID ; IntfID = CDC_DATA_INTF_ID?
  1596. cpfseq SetupPkt + bIntfID
  1597. USBCheckCDCRequestExit
  1598. return ; No
  1599.     
  1600. USBCheckCDCRequest1
  1601. movlw SEND_ENCAPSULATED_COMMAND ; Request = SEND_ENCAPSULATED_COMMAND?
  1602. cpfseq SetupPkt + bRequest
  1603. bra USBCheckCDCRequest2 ; No
  1604. mSetSourcePointer dummy_encapsulated_cmd_response
  1605. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  1606. movlw dummy_length
  1607. movwf wCount
  1608. clrf wCount + 1
  1609. bra USBCDCSetSessionOwner
  1610. USBCheckCDCRequest2
  1611. movlw GET_ENCAPSULATED_RESPONSE ; Request = GET_ENCAPSULATED_RESPONSE?
  1612. cpfseq SetupPkt + bRequest
  1613. bra USBCheckCDCRequest3 ; No
  1614. ;       // Populate dummy_encapsulated_cmd_response first.
  1615. mSetDestinationPointer dummy_encapsulated_cmd_response
  1616. bra USBCDCSetSessionOwner
  1617. USBCheckCDCRequest3
  1618. movlw SET_COMM_FEATURE ; Request = SET_COMM_FEATURE?
  1619. cpfseq SetupPkt + bRequest
  1620. bra USBCheckCDCRequest4 ; No
  1621. return ; Optional
  1622. USBCheckCDCRequest4
  1623. movlw GET_COMM_FEATURE ; Request = GET_COMM_FEATURE?
  1624. cpfseq SetupPkt + bRequest
  1625. bra USBCheckCDCRequest5 ; No
  1626. return ; Optional
  1627. USBCheckCDCRequest5
  1628. movlw CLEAR_COMM_FEATURE ; Request = CLEAR_COMM_FEATURE?
  1629. cpfseq SetupPkt + bRequest
  1630. bra USBCheckCDCRequest6 ; No
  1631. return ; Optional
  1632. USBCheckCDCRequest6
  1633. movlw SET_LINE_CODING ; Request = SET_LINE_CODING?
  1634. cpfseq SetupPkt + bRequest
  1635. bra USBCheckCDCRequest7 ; No
  1636. mSetDestinationPointer line_coding
  1637. bra USBCDCSetSessionOwner
  1638. USBCheckCDCRequest7
  1639. movlw GET_LINE_CODING ; Request = GET_LINE_CODING?
  1640. cpfseq SetupPkt + bRequest
  1641. bra USBCheckCDCRequest8 ; No
  1642. ; Abstract line coding information
  1643. movlw low 115200 ; baud rate
  1644. movwf line_coding + dwDTERate
  1645. movlw high 115200
  1646. movwf line_coding + dwDTERate + 1
  1647. movlw upper 115200
  1648. movwf line_coding + dwDTERate + 2
  1649. clrf line_coding + dwDTERate + 3
  1650. clrf line_coding + bCharFormat ; 1 stop bit
  1651. clrf line_coding + bParityType ; None
  1652. movlw 8
  1653. movwf line_coding + bDataBits ; 5,6,7,8, or 16
  1654. mSetSourcePointer line_coding
  1655. bcf usb_stat, ctrl_trf_mem ; Indicate RAM
  1656. movlw LINE_CODING_LENGTH
  1657. movwf wCount
  1658. clrf wCount + 1
  1659. bra USBCDCSetSessionOwner
  1660. USBCheckCDCRequest8
  1661. movlw SET_CONTROL_LINE_STATE ; Request = SET_CONTROL_LINE_STATE?
  1662. cpfseq SetupPkt + bRequest
  1663. bra USBCheckCDCRequest9 ; No
  1664. movff SetupPkt + wValue, control_signal_bitmap
  1665. bra USBCDCSetSessionOwner
  1666. USBCheckCDCRequest9
  1667. movlw SEND_BREAK ; Request = SEND_BREAK?
  1668. cpfseq SetupPkt + bRequest
  1669. bra USBCheckCDCRequest10 ; No
  1670. return ; Optional
  1671. USBCheckCDCRequest10
  1672. return ; Default
  1673. USBCDCSetSessionOwner
  1674. movlw MUID_CDC
  1675. movwf ctrl_trf_session_owner
  1676. return
  1679. ;/******************************************************************************
  1680. ; * Function:        void CDCInitEP(void)
  1681. ; *
  1682. ; * PreCondition:    None
  1683. ; *
  1684. ; * Input:           None
  1685. ; *
  1686. ; * Output:          None
  1687. ; *
  1688. ; * Side Effects:    None
  1689. ; *
  1690. ; * Overview:        CDCInitEP initializes CDC endpoints, buffer descriptors,
  1691. ; *                  internal state-machine, and variables.
  1692. ; *                  It should be called after the USB host has sent out a
  1693. ; *                  SET_CONFIGURATION request.
  1694. ; *                  See USBStdSetCfgHandler() in usb9.c for examples.
  1695. ; *
  1696. ; * Note:            None
  1697. ; *****************************************************************************/
  1698. CDCInitEP
  1699. movlw 2 ; Endpoint 2 In
  1700. movwf FSR0L
  1701. lfsr 1, cdc_notice ; FSR1 = endpoint buffer address
  1702. movlw CDC_INT_EP_SIZE ; W = endpoint size
  1703. rcall InitEPIn ; Inititalize the endpoint
  1705. movlw 3 ; Endpoint 3
  1706. movwf FSR0L
  1707. lfsr 1, cdc_data_rx ; FSR1 = endpoint buffer address
  1708. movlw CDC_BULK_OUT_EP_SIZE ; W = endpoint size
  1709. rcall InitEPOut ; Inititalize the endpoint
  1711. movlw 3 ; Endpoint 3 In
  1712. movwf FSR0L
  1713. lfsr 1, cdc_data_tx ; FSR1 = endpoint buffer address
  1714. movlw CDC_BULK_IN_EP_SIZE ; W = endpoint size
  1715. bra InitEPIn ; Inititalize the endpoint
  1717. #endif ; USB_USE_CDC
  1720. ; Generic code for use by all the classes
  1722. ; InitEPIn
  1723. ;  Generic initialize In endpoint
  1724. ; Input:
  1725. ;  FSR0L is endpoint number
  1726. ;  FSR1 is endpoint buffer address
  1727. ;  W is endpoint buffer size
  1728. ; Returns:
  1729. ;  Nada
  1730. ; Uses
  1731. ;  FSR0 is BDT pointer
  1732. ;  FSR1 is endpoint buffer pointer
  1733. ;  FSR2 is endpoint table pointer
  1735. InitEPIn
  1736. ; Save maximum count at front of endpoint buffer and move buffer pointer up (no need to put in Cnt for In)
  1737. movwf POSTINC1 ; Store maximum count at front of endpoint buffer and move up pointer
  1739. ; Point FSR2 to endpoint table
  1740. lfsr 2, UEP0
  1741. movf FSR0L, W ; Add in endpoint number
  1742. addwf FSR2L, F
  1744. ; Enable In endpoint
  1745. movlw EP_IN|HSHK_EN ; Enable In pipe
  1746. iorwf INDF2, F
  1748. ; Point FSR0 to endpoint BDT
  1749. rlncf FSR0L, W ; Endpoint number * 8
  1750. rlncf WREG, F
  1751. rlncf WREG, F
  1752. lfsr 0, ep0Bi ; Point FSR0 to beginning of BDT area
  1753. addwf FSR0L, F ; Add endpoint offset to FSR0 (can't overflow to FSR0H)
  1755. ; Set endpoint buffer address from FSR1
  1756. movlw ADRL ; Point to ADRL
  1757. movff FSR1L, PLUSW0
  1758. movlw ADRH ; Point to ADRH
  1759. movff FSR1H, PLUSW0
  1761. ; Set endpoint status
  1762. movlw _UCPU|_DAT1 ; Set transmit status
  1763. movwf INDF0 ; Set Stat
  1764. return
  1767. ; InitEPOut
  1768. ;  Generic initialize Out endpoint
  1769. ; Input:
  1770. ;  FSR0L is endpoint number
  1771. ;  FSR1 is endpoint buffer address
  1772. ;  W is endpoint buffer size
  1773. ; Returns:
  1774. ;  Nada
  1775. ; Uses
  1776. ;  FSR0 is BDT pointer
  1777. ;  FSR1 is endpoint buffer pointer
  1778. ;  FSR2 is endpoint table pointer
  1780. InitEPOut
  1781. ; Save maximum count at front of endpoint buffer and move buffer pointer up
  1782. movwf POSTINC1 ; Store maximum count at front of endpoint buffer and move up pointer
  1784. ; Point FSR2 to endpoint table
  1785. lfsr 2, UEP0
  1786. movf FSR0L, W ; Add in endpoint number
  1787. addwf FSR2L, F
  1789. ; Enable Out endpoint
  1790. movlw EP_OUT|HSHK_EN ; Enable Out pipe
  1791. iorwf INDF2, F
  1793. ; Point FSR0 to endpoint BDT
  1794. rlncf FSR0L, W ; Endpoint number * 8
  1795. rlncf WREG, F
  1796. rlncf WREG, F
  1797. lfsr 0, ep0Bo ; Point FSR0 to beginning of BDT area
  1798. addwf FSR0L, F ; Add endpoint offset to FSR0 (can't overflow to FSR0H)
  1800. ; Set endpoint buffer address from FSR1 + 1
  1801. movlw ADRL ; Point to ADRL
  1802. movff FSR1L, PLUSW0
  1803. movlw ADRH ; Point to ADRH
  1804. movff FSR1H, PLUSW0
  1806. ; Set Cnt to maximum count
  1807. movf POSTDEC1, W ; Back up endpoint buffer pointer (no PREDEC1!)
  1808. incf FSR0L, F ; Point to Cnt
  1809. movff INDF1, POSTDEC0 ; Set maximum count and point back to Stat
  1811. ; Set endpoint status
  1812. movlw _USIE|_DAT0|_DTSEN ; Set receive status
  1813. movwf INDF0 ; Set Stat
  1814. return
  1817. ; PutUSB
  1818. ;  Generic fill In endpoint for TX
  1819. ; Input:
  1820. ;  FSR0L is endpoint number
  1821. ;  FSR1 is source buffer pointer
  1822. ;  W is count
  1823. ; Returns:
  1824. ;  FSR1 is updated source buffer pointer
  1825. ;  W returns number sent
  1826. ;  Carry is clear for buffer not available
  1827. ; Uses:
  1828. ;  FSR0 is BDT pointer
  1829. ;  FSR1 is source buffer pointer
  1830. ;  FSR2 is endpoint buffer pointer
  1831. ;  R0 in BANKA is temporary length storage
  1833. PutUSB
  1834. movwf R0 ; Save count
  1836. ; Check to see if we're configured
  1837. movlb high 0x400 ; Point to proper bank
  1838. movlw CONFIGURED_STATE ; We might not be configured yet
  1839. subwf usb_device_state, W
  1840. movlw 0 ; 0 characters sent, so far
  1841. bcf STATUS, C ; Clear Carry for possible error return
  1842. bnz PutUSBNotReady ; We're not configured
  1844. ; Point FSR0 to requested endpoint In BDT
  1845. rlncf FSR0L, W ; Endpoint number * 8
  1846. rlncf WREG, F
  1847. rlncf WREG, F
  1848. lfsr 0, ep0Bi ; Point FSR0 to beginning of BDT area
  1849. addwf FSR0L, F ; Add endpoint offset to FSR0 (can't overflow to FSR0H)
  1851. movlw 0 ; 0 characters sent, so far
  1852. bcf STATUS, C ; Clear Carry for possible error return
  1853. btfsc INDF0, UOWN ; Who owns the buffer (Stat, UOWN)?
  1854. PutUSBNotReady
  1855. return ; Busy (we don't)
  1857. ; Get endpoint buffer address to FSR2
  1858. movlw ADRL ; Point to ADRL
  1859. movff PLUSW0, FSR2L
  1860. movlw ADRH ; Point to ADRH
  1861. movff PLUSW0, FSR2H
  1863. movlw -1
  1864. movf PLUSW2, W ; Get maximum length from in front of endpoint buffer
  1866. cpfslt R0 ; Find number of bytes to send this time
  1867. movwf R0 ; Too big - send maximum allowed length
  1869. incf FSR0L, F ; Point to Cnt
  1870. movf R0, W ; Get number to send
  1871. movwf POSTDEC0 ; Put length into Cnt and point back to Stat
  1872. bz PutUSBZero ; Zero to send
  1874. PutUSBRamLoop
  1875. movff POSTINC1, POSTINC2 ; Copy source buffer to endpoint buffer
  1876. decfsz WREG, F ; Count down number of bytes to transfer
  1877. bra PutUSBRamLoop
  1879. PutUSBZero
  1880. movlw _DTSMASK ; Save only DTS bit
  1881. andwf INDF0, F
  1882. btg INDF0, DTS ; Toggle DTS bit
  1883. movlw _USIE|_DTSEN ; Turn ownership to SIE
  1884. iorwf INDF0, F
  1885. movf R0, W ; Return number of bytes sent
  1886. bsf STATUS, C ; Set Carry for non-error return
  1887. return
  1890. ; GetUSB
  1891. ;  Generic get from Out endpoint for RX
  1892. ; Input:
  1893. ;  FSR0L is endpoint number
  1894. ;  FSR1 is destination buffer pointer
  1895. ;  W is max buffer length
  1896. ; Returns:
  1897. ;  FSR1 is updated destination buffer pointer
  1898. ;  W returns number received
  1899. ;  Carry is clear for buffer not available
  1900. ; Uses
  1901. ;  FSR0 is BDT pointer
  1902. ;  FSR1 is destination buffer pointer
  1903. ;  FSR2 is endpoint buffer pointer
  1904. ;  R0 in BANKA is temporary length storage
  1906. GetUSB
  1907. movwf R0 ; Save max buffer length
  1909. ; Check to see if we're configured
  1910. movlb high 0x400 ; Point to proper bank
  1911. movlw CONFIGURED_STATE ; We might not be configured yet
  1912. subwf usb_device_state, W
  1913. movlw 0 ; 0 characters received, so far
  1914. bcf STATUS, C ; Clear Carry for possible error return
  1915. bnz GetUSBNotReady ; We're not configured
  1917. ; Point FSR0 to requested endpoint Out BDT
  1918. rlncf FSR0L, W ; Endpoint number * 8
  1919. rlncf WREG, F
  1920. rlncf WREG, F
  1921. lfsr 0, ep0Bo ; Point FSR0 to beginning of BDT area
  1922. addwf FSR0L, F ; Add endpoint offset to FSR0 (can't overflow to FSR0H)
  1924. movlw 0 ; 0 characters received, so far
  1925. bcf STATUS, C ; Clear Carry for possible error return
  1926. btfsc INDF0, UOWN ; Who owns the buffer (Stat, UOWN)?
  1927. GetUSBNotReady
  1928. return ; Busy (we don't)
  1930. ; Get endpoint buffer address to FSR2
  1931. movlw ADRL ; Point to ADRL
  1932. movff PLUSW0, FSR2L
  1933. movlw ADRH ; Point to ADRH
  1934. movff PLUSW0, FSR2H
  1936. movf PREINC0, W ; Get Cnt
  1937. cpfslt R0 ; Make sure it's not longer than the buffer
  1938. movwf R0 ; It's OK, save returned length
  1940. movlw -1
  1941. movf PLUSW2, W ; Get maximum length from in front of endpoint buffer
  1942. movwf POSTDEC0 ; Reset max length and point back to Stat
  1944. movf R0, W ; Get count to W
  1945. bz GetUSBZero ; Nothing received
  1947. GetUSBRamLoop
  1948. movff POSTINC2, POSTINC1 ; Copy endpoint buffer to destination buffer
  1949. decfsz WREG, F ; Count down number of bytes
  1950. bra GetUSBRamLoop
  1952. GetUSBZero
  1953. movlw _DTSMASK ; Save only DTS bit
  1954. andwf INDF0, F
  1955. btg INDF0, DTS ; Toggle DTS bit
  1956. movlw _USIE|_DTSEN ; Turn ownership to SIE
  1957. iorwf INDF0, F
  1958. movf R0, W ; Return number of bytes received
  1959. bsf STATUS, C ; Set Carry for non-error return
  1960. return