ERP-EIP-OA-Portal

Development Platform:
Visual Basic

frmUser.frm：Code Content
							VERSION 5.00
Begin VB.Form frmUser 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "管理员信息"
   ClientHeight    =   2775
   ClientLeft      =   2760
   ClientTop       =   3750
   ClientWidth     =   5235
   LinkTopic       =   "Form1"
   MaxButton       =   0   'False
   MinButton       =   0   'False
   ScaleHeight     =   2775
   ScaleWidth      =   5235
   ShowInTaskbar   =   0   'False
   Begin VB.CommandButton OKButton 
      Caption         =   "确定"
      Height          =   330
      Left            =   2280
      TabIndex        =   4
      Top             =   2280
      Width           =   1215
   End
   Begin VB.CommandButton CancelButton 
      Caption         =   "取消"
      Height          =   330
      Left            =   3720
      TabIndex        =   5
      Top             =   2280
      Width           =   1215
   End
   Begin VB.Frame fraMerchType 
      Caption         =   "管理员信息"
      Height          =   1815
      Left            =   240
      TabIndex        =   0
      Top             =   240
      Width           =   4455
      Begin VB.TextBox txtConfirmPwd 
         Height          =   375
         IMEMode         =   3  'DISABLE
         Left            =   1320
         MaxLength       =   20
         PasswordChar    =   "*"
         TabIndex        =   3
         Text            =   "txtRemark"
         Top             =   1200
         Width           =   2535
      End
      Begin VB.TextBox txtPwd 
         Height          =   375
         IMEMode         =   3  'DISABLE
         Left            =   1320
         MaxLength       =   20
         PasswordChar    =   "*"
         TabIndex        =   2
         Text            =   "txtRemark"
         Top             =   731
         Width           =   2535
      End
      Begin VB.TextBox txtName 
         Height          =   375
         Left            =   1320
         MaxLength       =   18
         TabIndex        =   1
         Text            =   "txtName"
         Top             =   263
         Width           =   2535
      End
      Begin VB.Label Label3 
         AutoSize        =   -1  'True
         Caption         =   "确认密码"
         Height          =   180
         Left            =   360
         TabIndex        =   8
         Top             =   1320
         Width           =   720
      End
      Begin VB.Label Label1 
         AutoSize        =   -1  'True
         Caption         =   "用户名"
         Height          =   180
         Left            =   360
         TabIndex        =   7
         Top             =   360
         Width           =   540
      End
      Begin VB.Label Label2 
         AutoSize        =   -1  'True
         Caption         =   "密码"
         Height          =   180
         Left            =   360
         TabIndex        =   6
         Top             =   840
         Width           =   360
      End
   End
End
Attribute VB_Name = "frmUser"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Private OK As Boolean             '确定用户按了OK还是CANCEL按钮
Private m_obj As clsAdmin         '数据对象，用来存储用户输入数据
Public m_ViewType As gxcViewType  '显示状态，指添加还是修改
'根据是“新增”还是修改，确定显示内容
Private Sub SetStatus()
  
  '设置控件默认值
  Call SetDefaultValue
  
  txtName.Locked = True
  
  '设置状态
  Select Case m_ViewType
  Case vtadd    '添加
    txtName.Locked = False
    CancelButton.Visible = True
    OKButton.Caption = "确定"
  Case vtModify '修改
    CancelButton.Visible = True
    OKButton.Caption = "保存"
  Case vtInfo   '查看
    CancelButton.Visible = False
    OKButton.Caption = "关闭"
  End Select
End Sub
'打开对话框，并传出用户输入数据
Public Function ShowDlg(ByRef obj As Object, _
                        ByVal eViewType As gxcViewType) As Boolean
  '保存数据
  Set m_obj = obj         '用户输入数据存放于此对象中
  m_ViewType = eViewType  '对话框状态
  
  '根据新增、编辑或查看设置显示内容
  SetStatus
  
  '显示对话框
  OK = False
  Me.Show vbModal
  If OK = False Then
    ShowDlg = False
    Exit Function
  End If
  
  '保存数据
  Set obj = m_obj
  
  '返回并释放对话框
  ShowDlg = True
  Unload Me
  
End Function
'设置控件默认值
Private Sub SetDefaultValue()
  Dim ctl As Control
  Dim i As Integer
  
 
 '如果是新增，则清空所有文本框
 '此处判断 m_obj为空与判断m_ViewType = vtAdd等效，但更安全
  If m_obj Is Nothing Then
    For Each ctl In Controls
      If TypeOf ctl Is TextBox Then
        ctl.Text = ""
      End If
    Next
  Else  '用传入对象的值更新数据
    With m_obj
      txtName.Text = .Account
      txtPwd.Text = .Pwd
      txtConfirmPwd.Text = .Pwd
    End With
  End If
  
End Sub
'检查输入有效性
Private Function CheckValid() As Boolean
  If txtName.Text = "" _
    Or txtPwd.Text = "" _
    Or txtConfirmPwd.Text = "" Then
    MsgBox "请填写完毕以上各项内容"
    CheckValid = False
    Exit Function
  End If
  If txtConfirmPwd.Text <> txtPwd Then
    MsgBox "两次密码输入不一致"
    CheckValid = False
    Exit Function
  End If
  CheckValid = True
  
End Function
'保存数据
Private Sub SaveValue()
  '给“成员变量”对象赋值
  With m_obj
    '注意以下利用RealString函数替换去除输入中的单引号
    .Account = RealString(txtName.Text)
    .Pwd = RealString(txtPwd.Text)
  End With
End Sub
'取消按钮
Private Sub CancelButton_Click()
  Me.Hide
End Sub
'确定按钮
Private Sub OKButton_Click()
  OK = True
  
  '检测输入有效性
  If Not CheckValid Then Exit Sub
  
  '如果是新增状态，则初始化一个数据对象
  If m_ViewType = vtadd Then Set m_obj = New clsAdmin
  
  '保存用户输入
  SaveValue
  Me.Hide
  
End Sub

						