ADO-ODBC

Development Platform:
ASP/ASPX

ShowReviewList.asp：Code Content
							<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<% Option Explicit %>
<%session.CodePage="936"%>
<!--#include file="FS_Inc/Const.asp" -->
<!--#include file="FS_InterFace/MF_Function.asp" -->
<!--#include file="FS_Inc/Function.asp" -->
<!--#include file="FS_Inc/Func_Page.asp" -->
<%dim cssnum
cssnum = Request.Cookies("FoosunUserCookies")("UserLogin_Style_Num")
if isnull(cssnum) or cssnum="" then cssnum = "2"
%>
<html xmlns="http://www.w3.org/1999/xhtml">
<title>查看评论---网站内容管理系统</title>
<meta name="keywords" content="风讯cms,cms,FoosunCMS,FoosunOA,FoosunVif,vif,风讯网站内容管理系统">
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<meta content="MSHTML 6.00.3790.2491" name="GENERATOR" />
<meta name="Keywords" content="Foosun,FoosunCMS,Foosun Inc.,风讯,风讯网站内容管理系统,风讯系统,风讯新闻系统,风讯商城,风讯b2c,新闻系统,CMS,域名空间,asp,jsp,asp.net,SQL,SQL SERVER" />
<link href="<%=G_USER_DIR%>/images/skin/Css_<%=cssnum%>/<%=cssnum%>.css" rel="stylesheet" type="text/css">
<head>
<body>
<table width="98%" border="0" align="center" cellpadding="3" cellspacing="1">
  <tr>
    <td><%
	Response.Buffer = True
	Response.Expires = -1
	Response.ExpiresAbsolute = Now() - 1
	Response.Expires = 0
	Response.CacheControl = "no-cache"
	response.Charset = "gb2312"
	Dim User_Conn,review_Sql,review_RS,review_RS1,strShowErr,Cookie_Domain
	Dim Server_Name,Server_V1,Server_V2
	Dim TmpStr,TmpArr,ReviewTypes
	Dim stype,Id,SpanId
	TmpStr = "" 
	Dim Conn 
	  
	MF_Default_Conn
	Cookie_Domain = Get_MF_Domain()
	if Cookie_Domain="" then 
		Cookie_Domain = "localhost"
	else
		if left(lcase(Cookie_Domain),len("http://"))="http://" then Cookie_Domain = mid(Cookie_Domain,len("http://")+1)
		if right(Cookie_Domain,1)="/" then Cookie_Domain = mid(Cookie_Domain,1,len(Cookie_Domain) - 1)
	end if	
	''防盗连
	Server_Name = Len(Request.ServerVariables("SERVER_NAME"))
	Server_V1 = Left(Replace(Cstr(Request.ServerVariables("HTTP_REFERER")),"http://",""),Server_Name)
	Server_V2 = Left(Cstr(Request.ServerVariables("SERVER_NAME")),Server_Name)
	if Server_V1 <> Server_V2 and Server_V1 <> "" and Server_V2 <> "" then
		response.Write("没有权限，请访问<a href=""http://"&Cookie_Domain&""">"&Cookie_Domain&"</a>.")
		response.End()
	end if
	
	stype = NoSqlHack(request.QueryString("type")) 'NS
	Id = NoSqlHack(request.QueryString("Id")) 'Id
	if stype="" then response.Write("Error:type is null!</body></html>")  :  response.End()
	if Id="" or not isnumeric(Id) then response.Write("Error:Id is no number!</body></html>")  :  response.End()
	select case stype
		case "NS"
		ReviewTypes=0
		case "DS"
		ReviewTypes=1
		case "MS"
		ReviewTypes=2
		case "HS"
		ReviewTypes=3
		case "SD"
		ReviewTypes=4
		case "LOG"
		ReviewTypes=5	
		case else
			response.Write("Error:type("&stype&") is not found!</body></html>")  :  response.End()
	end select
	
	MF_User_Conn
	
	
	Dim int_RPP,int_Start,int_showNumberLink_,str_nonLinkColor_,toF_,toP10_,toP1_,toN1_,toN10_,toL_,showMorePageGo_Type_,cPageNo
	int_RPP=15 '设置每页显示数目
	int_showNumberLink_=10 '数字导航显示数目
	showMorePageGo_Type_ = 1 '是下拉菜单还是输入值跳转，当多次调用时只能选1
	str_nonLinkColor_="#999999" '非热链接颜色
	toF_="<font face=webdings>9</font>"   			'首页 
	toP10_=" <font face=webdings>7</font>"			'上十 
	toP1_=" <font face=webdings>3</font>"			'上一
	toN1_=" <font face=webdings>4</font>"			'下一
	toN10_=" <font face=webdings>8</font>"			'下十
	toL_="<font face=webdings>:</font>"				'尾页
	
	Function review_Data()	
		On Error Resume Next
		Dim UserName
		UserName=""
		review_Data = "<table border=0 width=""100%"" cellspacing=""1"" cellpadding=""2"" align=center class=""table"">"&vbNewLine
		review_Data = review_Data & "<tr><td class=""xingmu"">所有评论：</td></tr>"&vbNewLine
		review_Sql = "select ReviewID,UserNumber,Title,Content,AddTime,ReviewIP from FS_ME_Review where isLock=0 and AdminLock=0 and ReviewTypes="&ReviewTypes&" and InfoID="&ID&" order by ReviewID desc"
		set review_RS = CreateObject(G_FS_RS)
		review_RS.Open review_Sql,User_Conn,1,1
		if Err<>0 then 
			Err.Clear
			review_Data = "<tr><td colspan=2>抱歉，系统错误。</td></tr></table>"&vbNewline:exit function
		end if	
		if review_RS.eof then
			review_Data = "<tr><td colspan=2>抱歉，暂无评论。</td></tr>"&vbNewline
		else
			review_RS.PageSize=int_RPP
			cPageNo=NoSqlHack(Request.QueryString("Page"))
			If cPageNo="" Then cPageNo = 1
			If not isnumeric(cPageNo) Then cPageNo = 1
			cPageNo = Clng(cPageNo)
			If cPageNo<=0 Then cPageNo=1
			If cPageNo>review_RS.PageCount Then cPageNo=review_RS.PageCount 
			review_RS.AbsolutePage=cPageNo
			
			  FOR int_Start=1 TO int_RPP 
			  
				set review_RS1=User_Conn.execute("select UserName from FS_ME_Users where UserNumber='"&review_RS("UserNumber")&"'")
				if not review_RS1.eof then 
					UserName = review_RS1("UserName")
					'if session("FS_UserNumber")<>"" then 
						UserName = "·<a href=""http://"&Cookie_Domain&"/"&G_USER_DIR&"/ShowUser.asp?UserNumber="&review_RS("UserNumber")&""" title=""点击查看该用户信息"" target=""_blank"">"&UserName&"</a>"
					'end if
				else
					UserName = "·匿名"	
				end if
				review_Data = review_Data &"<tr><td class=""hback_1"" height=""26"">"&UserName&"&nbsp;&nbsp;"&review_RS("Title")&"&nbsp;&nbsp;日期:"&review_RS("AddTime")&"&nbsp;&nbsp;IP:"&showip(review_RS("ReviewIP"))&"</td></tr>"&vbNewLine
				review_Data = review_Data &"<tr><td height=""30"" class=""hback""><font style=""font-size:14px"">"&Replace(Replace(Replace(review_RS("Content"),CHR(13),""),CHR(10)&CHR(10),"</P><P>"),CHR(10),"<BR>")&"</font></td></tr>"&vbNewLine
				review_RS1.close
				review_RS.movenext
				if review_RS.eof or review_RS.bof then exit for
			  NEXT
			  review_Data = review_Data &"<tr><td>"& fPageCount(review_RS,int_showNumberLink_,str_nonLinkColor_,toF_,toP10_,toP1_,toN1_,toN10_,toL_,showMorePageGo_Type_,cPageNo) &"</td></tr>"&vbNewLine
		end if
		review_Data = review_Data &"<tr><td align=center><button onClick=""window.close();"">关 · 闭</button></td></tr>"&vbNewLine
		review_Data = review_Data &"</table>"&vbNewLine	
	End Function
	function showip(ip)
		dim tmp_1,arr_1,ii_1
		tmp_1 = ""
		if ip="" or isnull(ip) then showip="":exit function
		arr_1 = split(ip,".")
		for ii_1=0 to ubound(arr_1)
			if ii_1<2 then 
				tmp_1 = tmp_1 &"."&arr_1(ii_1)
			else
				tmp_1 = tmp_1 & ".*"
			end if		
		next
		showip = mid(tmp_1,2)
	end function
	
	response.Write(review_Data())
	User_ConnClose()
	
	Sub RsClose()
		review_RS.Close
		Set review_RS = Nothing
	end Sub
	
	Sub User_ConnClose()
		Set Conn = Nothing
		Set User_Conn = Nothing
		response.Write(vbNewline&"</body></html>")
		response.End()
	End Sub
%></td>
  </tr>
</table>
</body>
</html>

						